How Come You Guys Don't Use .WSF Files?

re: How Come You Guys Don't Use .WSF Files?

Andreas Häber — Tue, 24 Feb 2004 16:23:00 GMT

I used .wsf files last year :)

I really liked the usage-tags, but it would be really nice if it took care of error-handling for usage as well. (Seems like this will come in MSH (see http://microsoft.sitestream.com/PDC2003/ARC/ARC334.htm), so I'm looking forward to that one! Lot's of other features to look forward to in MSH as well :))

What I used the .wsf scripts for was to run tests of a system written in C++. So, with that background I really liked the include-feature as well :). Lot's of the tests had things in common, so for me it was natural to split those out in it's own file and include it.

For me the WSH environment is nice to create tests, since it's easy to get information from the system+network using WMI and such. Creating the tests with c++ would've taken a lot more time and effort IMO.

re: How Come You Guys Don't Use .WSF Files?

IM — Tue, 24 Feb 2004 17:58:00 GMT

I used wsf files to write scripts that generated software patches, lots of file copying, calling of regssvr32 stopping/starting services, MTS package stuff.
Then recently, I rewrote it in C# - I'm an intellisense kind of a guy! Much nicer environment to code in, even for 'scripty' tasks.
I used the 'job' facility, but found that ultimately it caused me more confusion than it helped. I had a bunch of BAT files that ran other batch files that ran jobs in the WSF file. What a mess!
Can't see myself using WSF again, but I think I am one of those people who is 'allergic' to run-time checked languages in general. I hated python too. :-)

re: How Come You Guys Don't Use .WSF Files?

Peter Forret — Tue, 24 Feb 2004 19:03:00 GMT

I've been using WSF scripts for more than a year now, and I do not make .vbs scripts anymore. Why?
I don't use the 'multiple jobs' feature.
I don't use the 'multiple languages' feature (I'm a VBScript guy)
I don't use the 'type library' feature.
...
But one simple feature alone makes it worthwhile, one you didn't mention. It's the integrated option parsing (which is related to your 'usage' feature)
I can specify my options in any order, not use them if I don't want to and simply use WScript.Arguments.Named to access them.
I've added a small wrapper library I include in all my scripts that allows me to do
sSITE =GetNamedString("site","none")
(get the /site:yyy option, or if it's not specified, give me default value 'none')

E.g: one of my scripts is a timer/stopwatch.
Usage: waTimer.wsf CMD PARAM [/total:value] [/bar:value] [/calc:value] [/unit:value] [/scale:value] [there's more but you get the picture ...]
I can call it as
waTimer STOP COPYJOB /total:1000 or
waTimer /total:1000 /scale:60 STOP COPYJOB /unit:KB/min
Trivial, but really handy.

Another thing I use in WSF is the <resource> tag:
<resource id="History">
* v1.1 - 2004-02-24 - Bugfix - enhanced performance
* v1.0 - 2004-01-13 - First public release
</resource>

I use it to have all my version/name/copyright/... information in easy editable tags in the first 20 lines of my script, and then use them as getResource("History") further on. This is a nice-to-have, I know.

If you want to see the templates I made for .wsf scripts, check out http://winadmin.sourceforge.net .

Love the blog by the way,

Peter

re: How Come You Guys Don't Use .WSF Files?

Steven Griffiths — Tue, 24 Feb 2004 22:05:00 GMT

I've used the .wsf format in my scripts for about 6 months now and use it mainly for the usage instructions and to include a standard set of subroutines (mainly logging and error handling related) into my scripts. Sure, I could just cut and paste the routines and have a single file, but I have a deployment solution that comprises several scripts and each needs access to the logging and error handling routines. Including a single file simply means there's less code to manage.

I take it you're not a .wsf file fan then?

So when are Dean, Bob and Ethan going to contribute to this blog? Seems a bit unfair to leave all the work to one man! Which one of the is pro- .wsf?

Scripting: XML (.wsf) vs.

Paul's Imaginary Friend — Wed, 25 Feb 2004 12:05:00 GMT

re: How Come You Guys Don't Use .WSF Files?

Eric Lippert — Thu, 26 Feb 2004 16:05:00 GMT

I've posted some comments following up on various issues raised in this entry.

http://weblogs.asp.net/ericlippert/archive/2004/02/25/80139.aspx#80450

re: How Come You Guys Don't Use .WSF Files?

Tarjei T. Jensen — Tue, 02 Mar 2004 13:21:00 GMT

Eric Lippert's comments are to the point.

However I'd like to point out that .wsf messes up the structure of the script. You really don't want to have all that extranous stuff there.

Includes and constants are nice, but it is more important that the script reads well. BTW A readable programming language is usally more verbose than the other ones.

greetings,

re: How Come You Guys Don't Use .WSF Files?

Bob Riemersma — Sat, 06 Mar 2004 05:12:00 GMT

Gonna hold my nose and hope markup brackets don't break something here...

Speaking of <resource> tags:

<job>
<object id="objFSO" progid="Scripting.FileSystemObject"/>
<reference object="ADODB.Recordset"/>
<object id="objRS" progid="ADODB.Recordset"/>

<reference guid="{00020813-0000-0000-C000-000000000046}"/>
<object id="objXL" progid="Excel.Application.9"/>
<resource id="strConnection">
Provider="Microsoft.Jet.OLEDB.4.0";
Extended Properties="Text";
Data Source="LogFiles"
</resource>
<resource id="sqlJoin">
SELECT
[Employee ID],
[Last Name],
[First Name],
[Middle Initial],
AU,
[Job Title],
Left(DUMP.NTID, InStr(DUMP.NTID, "\") - 1) AS [Domain],
Mid(DUMP.NTID, InStr(DUMP.NTID, "\") + 1) AS [User's Name],
Workstation
FROM Dump.txt AS DUMP
INNER JOIN DCLogs.csv AS DCLOGS ON DUMP.NTID = DCLOGS.NTID
WHERE DUMP.[Employee ID] IS NOT NULL
ORDER BY [Last name] ASC, [First Name] ASC, [Middle Initial] ASC;
</resource>
<script language="VBScript">
Option Explicit

Dim objFld, lngFlds
Dim objWB, objWS, lngCol, strXLWB

strXLWB = WScript.ScriptFullName
strXLWB = Left(strXLWB, InStrRev(strXLWB, "\")) & "Report.xls"
If objFSO.FileExists(strXLWB) Then
objFSO.DeleteFile strXLWB
End If

objRS.Open getResource("sqlJoin"), _
getResource("strConnection"), _
adOpenForwardOnly
lngFlds = objRS.Fields.Count

Set objWB = objXL.Workbooks.Add
Set objWS = objWB.WorkSheets(1)
With objWS
.Activate
For lngCol = 1 To lngFlds
.Cells(1, lngCol) = objRS.Fields(lngCol - 1).Name
Next
.Rows("1:1").Font.Bold = True
.Rows("1:1").HorizontalAlignment = xlHAlignCenter
.Rows("2:2").CopyFromRecordset objRS
.Columns("A:" & Chr(Asc("@") + lngFlds)).AutoFit
.Rows("2:2").Select
objXL.ActiveWindow.FreezePanes = True
.Cells(1, 1).Activate
End With
Set objWS = Nothing
objRS.Close

objWB.SaveAs strXLWB, xlWorkbookNormal
Set objWB = Nothing
objXL.Quit
MsgBox "Report.xls Created"
</script>
</job>

Small example, and I left out the Schema.ini file guiding the Jet Text Driver. But you get the picture. The SQL is less of a hassle without concatenating a long string up inline.

re: How Come You Guys Don't Use .WSF Files?

Bob Riemersma — Sat, 06 Mar 2004 05:14:00 GMT

Got me!

Lost my leading whitespace. *sigh* Live and learn.

re: How Come You Guys Don't Use .WSF Files?

Alex Angelopoulos — Sat, 06 Mar 2004 12:43:00 GMT

I generally have the same feelings that Eric Lippert does about this: WSFs are VERY useful, but for the role that scripts in the script center currently have, they're a bit too much for clear communication of an idea.

That said, it is quite possible to completely automate validation of arguments for simple sets - in other words, if all of the arguments are a mix-and-match global group without any constraints (like "/A cannot be specified if /W is also specified, unless it is the third Wednesday in...")

At the bottom is the code for a WSC that does exactly this. Once registered on a system, you can call it from any XML-compliant WSF to automate validation of arguments; it will read the tags for your WSF and optionally the specific named job, then ensure that supplied commandline arguments match the named/unnamed specification.

Example code use in a WSF:

8< ---------------------------------
Set argEx = CreateObject("WshArgument.Extensions")
Set argEx.Wsh = WScript
argEx.RequireCScript = True
'argex.JobId = "main"
'argex.TraceExecution = True
'argex.AllowLooseTyping = True
'argex.ContinueOnFailure = True
'argex.ExitErrorLevel = True
argEx.ValidateArguments
'WScript.Echo "Was validation successful?", argEx.IsValid

8< ---------------------------------
and the WSC code:
8<----------------------------------
<?xml version="1.0" ?>
<package><component id="main">
<?component error="true" debug="true"?>
<registration progid="WshArgument.Extensions" classid="{790E104C-7A48-499F-8EDA-6D5CD0A56D93}" description="A WSF argument extension component, focusing on validation." remotable="no" version="1.0">
<script language="VBScript">
<![CDATA[
Function Register()
With CreateObject("Scriptlet.TypeLib")
.MajorVersion = 1: .MinorVersion = 0
.AddURL "wshargex.wsc"
.Path = "wshargex.tlb": .Name = .Path
.Doc = "A WSF argument extension component, focusing on validation."
.GUID = "{C920CF60-675F-4D7E-87E7-D9076F58BB20}"
.Write: .Reset
End With
End Function

Function Unregister(): End Function
]]></script>
</registration>
<public>
<property get name="IsValid" description="Whether or not the last invocation of ValidateArguments() returned a valid parse."/>
<property put name="Wsh" description="Object reference to the script host to pass in to the component."/>
<property get put name="TraceExecution" description=""/>
<property name="JobId" description=""/>
<property get put name="RequireCScript" description=""/>
<property get put name="AllowLooseTyping" description=""/>
<property get put name="ContinueOnFailure" description=""/>
<property get put name="ExitErrorLevel" description=""/>
<property get name="wshArgTypeSimple" description=""/>
<property get name="wshArgTypeBoolean" description=""/>
<property get name="wshArgTypeString" description=""/>
<method name="Simple" description="" internalname="get_Simple">
<parameter name="argName"/>
</method>
<method name="String" description="" internalname="get_String">
<parameter name="argName"/>
<parameter name="defaultValue"/>
</method>
<method name="Boolean" description="" internalname="get_Boolean">
<parameter name="argName"/>
</method>
<method name="ValidateArguments" description=""/>
</public>
<object id="fso" progid="Scripting.FileSystemObject"/>
<object id="xml" progid="MSXML2.DOMDocument"/>
<script language="VBScript"><![CDATA[
Option Explicit
'
' Initialization of global/public variables
'
Const wshArgTypeSimple = 0
Const wshArgTypeBoolean = 11
Const wshArgTypeString = 8
Dim AllowLooseTyping, ContinueOnFailure, ExitErrorLevel
Dim IsValid, JobId, RequireCScript, TraceExecution, Wsh

Initialize()

Sub Initialize()
xml.async = False
AllowLooseTyping = False
ContinueOnFailure = False
ExitErrorLevel = 2
IsValid = vbNull
JobId = vbNullString
RequireCScript = False
Set Wsh = Nothing
TraceExecution = 0
End Sub

function put_Wsh(value)
Set Wsh = value
end function

function get_TraceExecution()
get_TraceExecution = TraceExecution
end function
function put_TraceExecution(value)
TraceExecution = CBool(value)
end function

function get_RequireCScript()
get_RequireCScript = RequireCScript
end function
function put_RequireCScript(value)
RequireCScript = CBool(value)
end function

function get_AllowLooseTyping()
get_AllowLooseTyping = AllowLooseTyping
end function
function put_AllowLooseTyping(value)
AllowLooseTyping = CBool(value)
end function

function get_ContinueOnFailure()
get_ContinueOnFailure = ContinueOnFailure
end function
function put_ContinueOnFailure(value)
ContinueOnFailure = CBool(value)
end function

function get_ExitErrorLevel()
get_ExitErrorLevel = ExitErrorLevel
end function
function put_ExitErrorLevel(value)
ExitErrorLevel = CLng(value)
end Function

function get_IsValid()
get_IsValid = IsValid
end function

function ValidateArguments()
Trace "Entering ValidateArguments()"
' takes a ref to WScript as an argument.
' Proceeds to do full parse and assembly of argument data.
' To make checking IsValid unnecessary if we are NOT using
' the default exit on failure, this function returns True if the
' validation succeeded, false otherwise.
ValidateArguments = False
' We try to die on failures; this ensures that if errors and
' interaction are suppressed that we don't try to validate anyway.
' The fact that this is a function instead of a sub ensures that
' the user can actually TEST the return value without even looking
' at ValidationFailed as described above.
Trace "Checking Whether host is valid."
If Not ValidScriptHost(Wsh) Then Exit Function
Trace "Host is valid."
Trace "Loading script from " & Wsh.ScriptFullName
If Not xml.Load(Wsh.ScriptFullName) Then Exit Function
Trace "Loaded script successfully"
Dim root
if JobId = vbNullString Then
Trace "No job specified, checking all named/unnamed elements."
set root = xml
Else
Trace "job specified: " & JobId
set root = xml.selectSingleNode("//job[@id='" & JobId & "']")
end if
Dim node
Trace "starting named node validation."
For Each node in root.selectNodes("//named")
validateNamed node
Next
Trace "starting unnamed node validation."
validateUnNamed root.selectNodes("//unnamed")
ValidateArguments = IsValid
Trace "Exiting ValidateArguments() at end"
end function

private sub validateNamed(node)
' Look for required named arguments find or Die.
' takes collection of "named" nodes as an argument
dim name, value, nameType
name = NodeAttribValue(node, "name")
Trace "checking named argument node with name " & name
If Wsh.Arguments.Named.Exists(name) Then
Trace "This argument was found on the commandline as well"
If Not AllowLooseTyping Then
Trace "We require strict argument types."
' We need to validate argument types.
value = Wsh.Arguments.Named(name)
Trace "The commandline argument's vartype and value: " _
& VarType(value) & " " & value
nameType = tovbVarType( NodeAttribValue(node, "type") )
Trace "The argument spec is for an argument of type: " _
& nameType
If Not VarType(value) = nameType Then Die()
End If
ElseIf CBool( NodeAttribValue(node, "required") ) <> 0 then
Trace "This is a required argument, but it wasn't supplied."
' if required="true", confirm user supplied it or Die.
Die()
' Argument "Typechecking"
end if
end sub

private sub ValidateUnNamed(unnamedNodes)
dim MaxIsMin, required, node
required = 0: MaxIsMin = true
' count required arguments, determine whether this is open number
for each node in unnamedNodes
' see if argument count is unbounded
if toLong(NodeAttribValue(node, "many")) = 1 then MaxIsMin = false
' add the count of required arguments from the unnamed
required = required + toLong(NodeAttribValue( node, "required"))
next
Trace "We require " & required & " unnamed arguments."
Trace "Is the maximum unnamed count the same as minimum? " _
& CStr(MaxIsMin)
'now we test to see if we have enough
dim count: count = Wsh.Arguments.UnNamed.Count
If count < required then
Die()
ElseIf count = required Then
' we're fine - required = count
ElseIf MaxisMin Then
' We have more than the count and shouldn't. Die!
Die()
End If
end sub

private function NodeAttribValue(node, attributeName)
dim Attribute
set Attribute = node.attributes.getNamedItem(attributeName)
if typename(Attribute) = "Nothing" then
NodeAttribValue = Empty
else
NodeAttribValue = Attribute.nodeValue
end if
end function

private function tovbVarType(typeString)
' Casts a named argument type attribute value to a vb VarType value.
' If the type value is not recognized, this returns null.
select case lcase(typeString)
case "boolean" tovbVarType = vbBoolean
case "string" tovbVarType = vbString
case "simple" tovbVarType = vbEmpty
case else tovbVarType = vbNull
end select
end function

private function toLong(value)
' takes any normal numeric or boolean string and coerces to long;
' treats true as +1
if StrComp(value, "false", vbTextCompare) = 0 then
toLong = 0
elseif StrComp(value, "true", vbTextCompare) = 0 then
toLong = 1
else
toLong = CLng( value )
end if
end function

private function ValidScriptHost(host)
' This routine first confirms that the hosting class actually IS
' the WSH host - a necessity for using the WScript.Arguments
' collection at this point, and for throwing a usable error in
' another host. Strictly speaking, this is an ugly hack though.
' Someone could create a class with the name "IHost_Class", and
' a REALLY cool argument parser would take parsed arguments from
' anywhere. All of the validation checks here other than testing
' whether CScript is required as a host are designed to guard
' against accidental misuse by a scripter, not an end-user.
' I don't want to do the work that being cool would require, though.
If RequireCScript And Not HostIsCscript() Then
ValidScriptHost = False
' We're going to abort processing anyway, but let's try to
' Die() first. Trying to Die() will call the help, and then
' the user can see the note that the scripter (hopefully) put
' into the help text about needing cscript for some reason.
Die()
ElseIf Not (TypeName(host) = "IHost_Class") Then
' MsgBox. Ugly again...this is the only way to get the point
' across if an erstwhile user has his error display suppressed
' in Internet Explorer.
MsgBox "This class MUST be used from WSH. Currently hosted by:" _
& vbCrLf & TypeName(host)
ValidScriptHost = False
ElseIf host.Version < 5.6 Then
' We aren't going to be able to work on a lesser version of WSH.
' Just to be courteous, we will use WScript.Echo in case this is
' a console session...
Wsh.Echo "This code must be used within a WSF file hosted", _
"in WSH 5.6 or higher with VBScript 5 or higher installed."
Wsh.Echo "The correct version of WSH can be downloaded", _
"from http://msdn.microsoft.com/scripting."
Die()
Else
' We don't require cscript and we are indeed in WSH, so
' we're valid!
ValidScriptHost = True
End If
end function

private sub Die()
Trace "Entering Die()."
Trace "Value of ContinueOnFailure is: " & CStr(ContinueOnFailure)
IsValid = False
if Not ContinueOnFailure then
Trace "We are exiting on failures; you should see help text."
Wsh.Arguments.ShowUsage()
Wsh.Quit(ExitErrorLevel)
End If
end sub

private sub Trace(s)
If TraceExecution Then fso.GetStandardStream(2).WriteLine s
end sub

public function HostIsCscript()
HostIsCscript = _
LCase(Right(Wsh.FullName, 11)) = "cscript.exe"
Trace "Is the host is cscript? " & HostIsCscript
end function

function get_Simple(ByVal argName)
' Returns true/false for whether a simple argument ArgName was specified
get_Simple = Wsh.Arguments.Named.Exists(argName)
end function

function get_Boolean(ByVal argName)
' Get an optional boolean named argument if it exists;
' if it does not exist, return the default value.
If Wsh.Arguments.Named.Exists(argName) Then
get_Boolean = CBool(argName)
Else
get_Boolean = CBool(defaultValue)
End If
end function

function get_String(ByVal argName, ByVal defaultValue)
' If a string named argument was specified on the script's
' commandline, return it. If it wasn't, return a default value.
If Wsh.Arguments.Named.Exists(argName) Then
get_String = WScript.Arguments.Named(argName)
Else
get_String = defaultValue
End If
end function

function get_wshArgTypeSimple
get_wshArgTypeSimple = wshArgTypeSimple
end function
function get_wshArgTypeBoolean
get_wshArgTypeBoolean = wshArgTypeBoolean
end function
function get_wshArgTypeString
get_wshArgTypeString = wshArgTypeString
end function

]]></script>
<resource id="foo"><![CDATA[This is a test.]]></resource>
</component>
</package>

re: How Come You Guys Don't Use .WSF Files?

Jaspreet Deol — Wed, 28 Apr 2004 09:05:00 GMT

a way to avoid copying .vbs file into the .wsh file is to make .cls files instead.

Just add the following to your .vbs file and change the extension to .cls

class classname
.vbs file code
end class

and then in the .wsh file add at the top:

<script language="VBScript" src="ClassObjects\ ... the path name...\clsname.cls" />

and there you are! No more copying huge chunks of code!

re: How Come You Guys Don't Use .WSF Files?

Jaspreet Deol — Wed, 28 Apr 2004 10:10:00 GMT

I get an error when trying to run this:

Option Explicit
' *****************************************************************************
' Class: controller
' Created: 16 April 2004
' Version: 1.1
' Desc: This class monitors all the jobs where each job calculates one M.I.S
' statistic
'
' This allows for different jobs to be contained in a single file
' instead of multiple script files. Each job can be executed
' separately and is dealt as a seperate entity.
'
' Creator: JD08372
' *****************************************************************************

<package>
<Job id="users"> // 'cscript //Job:users controller.wsf
<script language="VBScript" src="classes\dbnames.cls"> </script>
<script language="VBScript">

Option Explicit

dim objdbnames
set objdbnames = New dbnames
dbnames.extract_serverdb_names

' Clean up and exit once done
Set objdbnames = Nothing
Quit()
</script>
</Job>
</package>

the dbnames.cls runs alone when the class wrapper is taken away.
I want to use the .wsf file as i have lots of classes like dbnames.

Please can someone help me asap??

my email address: jkd01@doc.ic.ac.uk

WSF Files for sending to the "Administrator of the Day"

Michael Schell — Fri, 30 Apr 2004 02:40:00 GMT

Well I too resisted bothering with WSF files until very recently. The change came as my company got acquired by a big lumbering multinational, whose techs had little experience with scripting.

I wrote a script to go out and force a "gpupdate /force" on all the computers in a particular OU to use in case of an emergency where we were blocking an executable using Software Restriction. I use WSH Remote Scripting, since some of the boxes seem to have configuraton pecularities that cause WMI's Win32_Process object to gag when run remotely. I like to spawn a separate Controller process for each targeted PC. That way the parent script doesn't have to wait around for a powered-down PC to time out before continuing to the next object. So I actually have three scripts: parent, a spawned controller script which in turn spawns a remote script.

Do I dare send three scripts to these guys and hope that months after my term date (yup, they're closing us down and telling us to relocate or get out) they'll have kept all three in the same folder when time comes to actually use it? Uh, I decided to wrap them all into a single WSF file, and enjoy the quick and dirty objArgs.ShowUsage() support for free.

Now that I have the boilerplate WSF set up, I'm finding myself using it for most of my administrative scripts that have to go out and connect to lots of PCs in turn, even if I don't anticipate that they'll get used by some poor Administrator Of The Day months after I'm gone :-)

re: How Come You Guys Don't Use .WSF Files?

Mark — Fri, 30 Jul 2004 20:19:00 GMT

How to use wsf file with C#?

Paradise Travel Vietnam

10000 — Mon, 02 Aug 2004 17:32:00 GMT

10000

Vietnam Paradise Travels

10000 — Mon, 02 Aug 2004 17:32:00 GMT

10000

Include files and ccripting? You bet - with WSF files!

Ken Schaefer — Fri, 03 Jun 2005 09:27:01 GMT

In ASP we've always been able to store common routines/classes in a separate file and use an #include...

Warum man f??r WSH-Scripte das wsf-Format verwenden sollte « Susanns Weblog

Warum man f??r WSH-Scripte das wsf-Format verwenden sollte « Susanns Weblog — Mon, 01 Oct 2007 10:40:37 GMT

PingBack from http://susanneurich.wordpress.com/2007/10/01/warum-man-fur-wsh-scripte-das-wsf-format-verwenden-sollte/

Incude statement - is there such a thing? | keyongtech

Incude statement - is there such a thing? | keyongtech — Thu, 22 Jan 2009 12:44:22 GMT

PingBack from http://www.keyongtech.com/1941758-incude-statement-is-there-such

The Scripting Guys First Blog How Come You Guys Don t Use WSF Files | Best Eye Cream

Mon, 08 Jun 2009 06:01:12 GMT

PingBack from http://besteyecreamsite.info/story.php?id=1568

The Scripting Guys First Blog How Come You Guys Don t Use WSF Files | work from home

Tue, 16 Jun 2009 14:41:45 GMT

PingBack from http://workfromhomecareer.info/story.php?id=22735

The Scripting Guys First Blog How Come You Guys Don t Use WSF Files | debt consolidator

Fri, 19 Jun 2009 18:06:50 GMT

PingBack from http://mydebtconsolidator.info/story.php?id=21743