jaredpar's WebLog : Anonymous Types

Names of Anonymous Type Members

Jared Parsons — Sat, 10 Nov 2007 03:46:40 GMT

Recently I was asked how can you get a list of anonymous type member names given a query of anonymous types. The quick answer is that you can use a quick bit of reflection to get back the names.

    Public Function GetAnonymousTypeMemberNames(Of T)(ByVal anonymousType As T) As List(Of String)
        Dim type = GetType(T)
        Dim list = New List(Of String)
        For Each cur In type.GetProperties(Reflection.BindingFlags.Public Or Reflection.BindingFlags.Instance)
            list.Add(cur.Name)
        Next
        Return list
    End Function

The longer question is how can you get back a list of anonymous type member names given a query result? As long as you know the query will be populated you can just use the first member to get your result.

        Dim q = From it In "astring" Select a = it, b = it & "b"
        GetAnonymousTypeMemberNames(q.First())

However you can't guarantee that a query will always have data in it. Another route is to consider the contract of the From ... Select statement. This will produce a query which implements IEnumerable(Of T). For a query T will be the anonymous type that is generated[1]. We can query the metadata of the returned type to get the System.Type for the anonymous type regardless of the type actually implementing IEnumerable(Of T).

        Dim q = From it In "astring" Select a = it, b = it & "b"
        Dim enumerableInterface = GetType(IEnumerable(Of ))
        Dim enumerableType = q.GetType().GetInterface(enumerableInterface.FullName)
        Dim anonymousTypeType = enumerableType.GetGenericArguments(0)

[1] This is assuming that you didn't write a query which returns a field directly and avoids creating the anonymous type.

Casting to an Anonymous Type

Jared Parsons — Mon, 01 Oct 2007 18:15:00 GMT

This discussion is building upon a previous post on how to acquire an anonymous type ... type.

The next question is, how can you cast an arbitrary object into an anonymous type? At a glance this doesn't seem possible as you cannot directly express the type of an anonymous type in code. For instance the following code is not legal.

 Dim o As Object = SomeCall() 
Dim x = Directcast(o, New With {.a = 5})

Even though it's not possible to directly express the type in code, we can indirectly express it via type inference. Anonymous Types are strongly typed in the compiler and it is possible to infer these types where inference is available.

 Public Function CastSpecial(Of T)(ByVal o As Object, ByVal t As T) As T 
    Return DirectCast(o, T)
 End Function

The above function allows us to perform a DirectCast as long as we have an instance of the type we want to cast to. Now we can call the code and passing in the appropriate anonymous type instance.

 Dim o As Object = SomeCall()
 Dim x = CastSpecial(o, New With {.a = 5})

There are a couple of caveats to this approach though.

The actual anonymous type and the one you are casting to must be exactly the same. No polymorphism can be involved.
The anonymous type must be created in the same assembly where you are performing the cast. Anonymous types are specific to the assembly they are created in so performing the cast accross assemblies will cause a InvalidCastException to occur.
It does needlessly create an object to perform the cast.

Coding Quiz: Anonymous Type Types

Jared Parsons — Wed, 01 Aug 2007 18:34:37 GMT

Question: How can you create a variable in VB which is typed as an anonymous type but not actually create an instance of that type?

Answer in comments.

Note, doing this is not particularly useful it came about while I was playing around with a feature a few days ago.