How do download Microsoft Webcasts (long Post) - By Ronny Ong
Link to article by Ronny Ong
A few months ago, I mentioned being able to download MSDN webcasts (ones
which do not already provide a download link). Since then, I have been
getting more emails than I can answer directly, so I am posting this script
and instructions. I have already shared this with people who have gotten it
to work, and the only problem they ever run into is getting the script
copied and pasted without long lines being wrapped. I shortened all the
lines to 70 characters or less, which should get past most newsgroup
readers. The only exception is the line containing the EVENTPAGE constant.
You will need to edit that line to be able to use this script anyway, so
follow the instructions in the comments.
Please understand that I am only posting this script to reduce the amount of
email I get, so obviously I would appreciate it if you think twice before
emailing me about it. There are a lot of detailed instructions in the script
because you need to read them, not because I enjoy typing. Thanks for your
co-operation.
If it's 2006 and you're reading this message from Google's archives and the
script doesn't work anymore, it's either because a bunch of idiots abused
it, forcing Microsoft to change the site format and block this procedure, or
because Microsoft changes their site format periodically anyway. Sorry.
Copy and paste the lines below into Notepad, and save with a vbs file
extension. You may need to disable or reconfigure your anti-virus software
to allow you to use vbs files.
' VBScript to download Microsoft LiveMeeting-based webcasts from:
' http://www.microsoft.com/seminar/events/webcasts/ondemand.mspx
' BY USING THIS SCRIPT, YOU ACKNOWLEDGE THAT YOU ACCEPT MICROSOFT'S
' LICENSE AGREEMENT ON THE LIVEMEETING WEB SITE. IF YOU HAVE NOT READ
' THE LICENSE AGREEMENT OR DO NOT ACCEPT IT, DO NOT USE THIS SCRIPT.
' YOU ARE SOLELY RESPONSIBLE FOR YOUR USE OF THIS SCRIPT. PLEASE
' DO NOT WASTE BANDWIDTH BY DOWNLOADING ENTIRE WEBCASTS UNLESS YOU
' REALLY INTEND TO WATCH THEM!
' IMPORTANT: Different organizations within Microsoft use different
' webcast formats. This script is designed for the pre-recorded
' LiveMeeting webcasts available to the public. It does NOT handle:
' - Live Webcasts (wait until they get posted for on-demand viewing)
' - Private LiveMeeting (used by MS Partner Readiness training; URL
' sent in registration email -- needs modified version of script)
' - Seminar Online (used by some but not all MSDN/TechNet webcasts;
' URL contains manifest.xml -- recent releases give download links)
' - PSS Support Webcasts (URL contains support.microsoft.com)
' - Interwise (used by product teams before MS acquired Placeware;
' URL contains file extension of vcm -- can be downloaded with
' right-click Save As)
' - WebEx (used by sales & technical sales support before MS acquired
' Placeware; URL contains file extension of wrf)
' - Other (outsourced to hosting services, used for special events
' such as new product launches -- download procedure varies)
' System Requirements:
' 1. Internet Explorer 6 (tested only with Service Pack 1)
' 2. Windows Media Player 7 or higher (tested only with 9)
' 3. NetTransport (freeware from xi-soft.com, tested only with 1.8x)
' Instructions:
' 1. Make sure cookies are enabled in IE. LiveMeeting requires this.
' 2. Change the EVENTPAGE constant below to the URL of the desired
' webcast's launch page (see example below).
' 3. Set the YOURNAME, COMPANY, and EMAIL constants below. Microsoft
' provides valuable content for free, so please give valid
' information. See the Privacy Policy on the Microsoft web site.
' 4. For best results, close all apps (especially IE windows and
' anything which is actively accessing the network/Internet)
' before running this script. It does not matter whether
' NetTransport is running as long as it is installed.
' 5. Run this script to add the Download Job to NetTransport. It will
' take a few seconds before you see anything happen. NetTransport
' will pop up and give you a chance to override the defaults
' before the download starts. The default filename will typically
' be placeware.wmv so you should enter a more descriptive name in
' the "Rename" textbox. Alternatively, you can wait until the
' download has finished, then right-click on it and choose "Comment
' as Filename" which will rename the file using the webcast
' description (extracted by this script for NetTransport's Comment
' field).
' Notes on NetTransport and Windows Media:
' 1. The actual downloading is done by NetTransport. If the Download
' Job doesn't start immediately, you might have set NetTransport to
' Manual Start. Right-click on the Job to Start it. Check other
' NetTransport options such as Proxies if you still have problems.
' 2. Windows Media Servers will not stream video faster than it is
' intended to be viewed. Even though you may have more bandwidth
' available, it will take as long to download the video as it would
' to to watch it. It is possible to serve Windows Media files via
' http, in which case you may be able to download faster, but none
' of the LiveMeeting webcasts are served that way.
' 3. If you cannot jump forward in the downloaded video, it was
' authored without indexing. This is common for asf/wmv format. To
' add indexing, you can use the Windows Media File Editor (part of
' the Windows Media Encoder, a free download from Microsoft) or you
' can simply right-click on the downloaded file in NetTransport and
' choose "Make Index for ASF..."
Option Explicit
' Example URL is for "Exchange 2003 in Multi-Forest Environments"
' The Const line may have been wrapped after you copied and pasted
' from your newsgroup reader, but it should all be one line.
Const EVENTPAGE =
"http://msevents.microsoft.com/CUI/EventDetail.aspx?EventID=1032252385&Culture=en-US"
Const YOURNAME = "Your Name"
Const COMPANY = "your Company Name"
Const EMAIL = "you@yourcompany.com"
Const VIEWPAGE = "http://www.placeware.com/cc/mseventsbmo"
Const MS_DELAY = 1000 ' higher than necessary, to be safe
Dim oIE
Dim oNetTransport
Dim sTitle
Dim oLinkTable
Dim oLink
Dim sHREF
Dim oForm
Dim sURL
Sub WaitForIE
WScript.Sleep MS_DELAY
Do While oIE.Busy
WScript.Sleep MS_DELAY
Loop
End Sub
Set oIE = CreateObject("InternetExplorer.Application")
WaitForIE
' oIE.Visible = True ' for debugging
oIE.Navigate EVENTPAGE
WaitForIE
sTitle = oIE.Document.All("lblEventTitle").InnerText
sTitle = Replace(sTitle, """", "'")
sTitle = Replace(sTitle, ":", "-")
sTitle = Replace(sTitle, "\", "-")
sTitle = Replace(sTitle, "?", "")
sTitle = Replace(sTitle, "*", "_")
sTitle = Replace(sTitle, "+", "&")
sTitle = Replace(sTitle, "/", "_")
Set oLinkTable = oIE.Document.All("lblEventDescription")
For Each oLink In oLinkTable.All.Tags("A")
If Left(oLink.HREF, Len(VIEWPAGE)) = VIEWPAGE Then
sHREF = oLink.HREF
Exit For
End If
Next
oIE.Navigate sHREF
WaitForIE
If InStr(oIE.LocationURL, "/support/maintenance") Then
' site is down for scheduled maintenance
oIE.Visible = True ' display the error page
WScript.Quit
End If
' Next page only appears if cookie doesn't exist
If oIE.Document.mainForm(1).Value = "Accept" Then
oIE.Document.mainForm.Elements(1).Click
WaitForIE
End If
oIE.Document.mainForm("cn").Value = YOURNAME
oIE.Document.mainForm.Submit
WaitForIE
oIE.Document.mainForm("email").Value = EMAIL
oIE.Document.mainForm("company").Value = COMPANY
oIE.Document.mainForm.Submit
WaitForIE
Set oForm = oIE.Document.Forms(0)
oForm.Action = "view.html?fmt=wmm"
oForm.Submit
WaitForIE
sURL = oIE.Document.All("Player7").URL
Set oNetTransport = CreateObject("NTIEHelper.NTIEAddUrl")
oNetTransport.AddLink EVENTPAGE, sURL, sTitle
Set oNetTransport = Nothing
oIE.Quit
====================================================================================================================
