System Center WebLog by Russ Slaten : SMS 2003

Running All Available Programs on an SMS 2003 Advanced Client

rslaten — Sat, 13 Oct 2007 00:22:00 GMT

Recently a customer complained that you can't run more than one advertised program at a time on a client, but they could in SMS 2.0. Here is an example VBScript that runs all available advertised programs on a client.

'rslaten 10/10/2007
'Example of how to run all available programs
'If you want to select some programs, but not all, then use C# or VB.NET to build a simple UI
'or accept parameters into this script to only run certain programs

Set UI = CreateObject("UIResource.UIResourceMgr")
Set ads = UI.GetAvailableApplications
For each o in ads
    WScript.Echo "DEBUG: Program = " & o.Name
    lastRunTime = o.LastRunTime
    bIsMandatoryProgramPending = UI.IsMandatoryProgramPending
    While bIsMandatoryProgramPending
        WScript.Sleep(10000)
        bIsMandatoryProgramPending = UI.IsMandatoryProgramPending
        WScript.Echo "DEBUG: Program is running, sleeping"
    WEnd
    WScript.Echo "DEBUG: Running program: " & o.Name
    UI.ExecuteProgram o.ID, o.PackageID, True
    bProgramComplete = false
    While Not bProgramComplete
        WScript.Echo "DEBUG: Checking if " & o.Name & " has completed running..."
        WScript.Sleep(10000)
        Set p = UI.GetProgram(o.ID, o.PackageID)
        If p.LastRunTime <> o.LastRunTime Then
            WScript.Echo "DEBUG: " & o.Name & " has completed running..."
            bProgramComplete = true
        End If
    WEnd
Next

The SMS MP for SCOM 2007 does not work properly if the SMS server is not installed to C:\SMS

rslaten — Wed, 19 Sep 2007 20:43:00 GMT

The SMS MP Guide actually tells you this:

"To specify the location of the SMS installation folder the script uses a system environment variable on the SMS site server. The administrator must create the %SMS_INSTALL_DIR_PATH% environment variable as a system environment variable so that the MOM Agent running under any user context has access to the log files. The script will then look in the %SMS_INSTALL_DIR_PATH%\Logs directory for the sender.log and distmgr.log files. For more information about setting system environment variables, see the system environment variable web page (<http://go.microsoft.com/fwlink/?LinkId=92316>).
In order for the MOM Health Agent to use this system environment variable the SMS Site Server may need to be restarted."

This seems easy enough, but what if you have thousands of site servers? My co-worker, Lenny Wile, ran into such a situation with a customer. Obviously at this point we need an automated method of setting this environment variable. Using SMS or SCOM a script such as this could be run on each site server to set the environment variable appropriately:

Set oWMI = GetObject("winMgmts:root\default:StdRegProv")
oWMI.GetStringValue &H80000002,"SOFTWARE\Microsoft\SMS\Setup","Installation Directory",sPath
Set oWMI = GetObject("winMgmts:root\cimv2:Win32_Environment")
Set oNewVar = oWMI.SpawnInstance_
oNewVar.UserName = "<SYSTEM>"
oNewVar.Name = "SMS_INSTALL_DIR_PATH"
oNewVar.VariableValue = sPath
oNewVar.Put_

For your reference, here is one of the errors you might see if this variable isn't set appropriately:

Error opening log file directory
Directory = %SMS_INSTALL_DIR_PATH%\Logs
Error: 0x80070003
Details: The system cannot find the path specified.
One or more workflows were affected by this.
Workflow name: SMS_2003_Component__The_sender_cannot_connect_to_remote_site_over_the_LAN__Advanced_Security__4_Rule
Instance name: Microsoft.SMS.2003.Microsoft_SMS_2003_Site_Servers_Installation
Instance ID: {34B6B4DF-3EF9-A320-7AD1-69EF7A68A288}

How the SMS 2003 Advanced Client Creates Delta Inventory

rslaten — Tue, 18 Sep 2007 22:10:00 GMT

I have recently done some research on exactly how inventory is generated, including deltas, and have listed the information below. This information can be obtained by monitoring the inventory agent logs, verbose WMI logs, and applicable inventory WMI classes:

Instruction to run inventory comes from an instance of InventoryAction. This specifies full, delta, or resync report type.
The state of each inventory action is stored in the InventoryActionStatus class.
Inventory history is stored in a class named after the inventory type (the C00…01 number for hinv)
Each instance is of the InventoryReport class
When inventory starts… (hinv in this example)
- If a delta is being specified, make sure a full report has already been generated (checks the InventoryActionStatus class)
- Prepares the applicable history class (deletes all non-current reports)
  - New instances are given a 'New' state
  - Updated instances are given an 'Updated' state
  - Instances that don't change are given a 'Verified' state
- Inventory is reported: Only 'New', 'Deleted', and 'Updated' instances are reported for deltas
- Cleans up applicable history class (creates 'Current' reports for all 'New', 'Updated', and 'Verified' reports)
- Sends inventory report via messaging system
- Updates the InventoryActionStatus class

How to Delete an Assignment from an SMS 2003 Advertisement

rslaten — Tue, 18 Sep 2007 21:20:00 GMT

I recently worked on an issue where a customer was trying to programmatically delete a mandatory assignment from an SMS 2003 advertisement. I saw that adding an assignment is a very easy and documented task, however deleting the same assignment is not.

Unfortunately I was only able to work on the issue for a few hours because I was going on vacation but one of my peers, David Stewart, figured it out while I was out. I thought this example would be useful for anyone looking to delete an assignment using a script.

' Parse cmd line args
' ==============================
sSiteCode = WScript.Arguments(0)
sAdvertID = WScript.Arguments(1)

' Connect to local site provider
' ==============================
Set objSWbemLocator = CreateObject("WbemScripting.SWbemLocator")
Set objSWbemServices = objSWbemLocator.ConnectServer(".", "root\sms")
Set ProviderLoc = objSWbemServices.InstancesOf("SMS_ProviderLocation")
For Each Location In ProviderLoc
    If Location.ProviderForLocalSite = True Then
        Set objSWbemServices = objSWbemLocator.ConnectServer(Location.Machine, "root\sms\site_" + Location.SiteCode)
        Set objSWbemLocator = Nothing
        Set ProviderLoc = Nothing
    End If
Next

' Retrieve the advertisment instance of concern
' =============================================
Set objAdvert = objSWbemServices.Get("SMS_Advertisement.AdvertisementID='" & sAdvertID & "'")

' Display advertisement properties
' ================================
WScript.Echo "ActionInProgress = " & objAdvert.ActionInProgress
WScript.Echo "AdvertFlags = " & objAdvert.AdvertFlags
WScript.Echo "AdvertisementID = " & objAdvert.AdvertisementID
WScript.Echo "AdvertisementName = " & objAdvert.AdvertisementName
WScript.Echo "CollectionID = " & objAdvert.CollectionID
WScript.Echo "Comment = " & objAdvert.Comment
WScript.Echo "Assigned Schedule = {"

' Display advertisement properties
' ================================
set Advertisement_Properties = objAdvert.Properties_ 'get property set
set AssignedScheduleArray = Advertisement_Properties.Item("AssignedSchedule")

' Display advertisement properties
' ================================
Dim replacementScheduleArray()

intSize = 0

' Loop through current assignments, copy them to new array to update advertisement instance.
' Leave any assignments we want to remove out of the new array.
' ==========================================================================================
for i = 0 to UBound(AssignedScheduleArray)

    'Retrieve next schedule token from instance array
    '================================================
    Dim SMS_ScheduleToken
    Set SMS_ScheduleToken = AssignedScheduleArray(i)
    
    'Display schedule token, ask if it should be deleted.
    '====================================================
    WScript.Echo AssignedScheduleArray.Name & " " & i & ":" & SMS_ScheduleToken.GetObjectText_()
    If MsgBox("Do you want to delete this assignment?", 4, "Assignment:" & SMS_ScheduleToken.StartTime) <> vbYes Then
        
        'Not deleting this schedule token, add it to the replacement array.
        '==================================================================
        redim preserve replacementScheduleArray(intSize)
        set replacementScheduleArray(intSize) = SMS_ScheduleToken.Clone_()
        intSize = intSize + 1
    end if
next
WScript.Echo "}"

'Update the advertisement instance with the replacement schedule token array
'===========================================================================
if(IntSize < 1) then
    'We removed all the schedule tokens.
    objAdvert.Properties_.Item("AssignedSchedule") = null   
else
    ' There is at least one value to keep
    objAdvert.Properties_.Item("AssignedSchedule") = replacementScheduleArray
end if
objAdvert.Put_()

The Mystery of the Lost Hardware Inventory

rslaten — Tue, 18 Sep 2007 20:37:00 GMT

In large environments, with tens of thousands of SMS 2003 clients, inventory may get "lost" for various reasons. An example of a lost inventory is below:

An SMS 2003 Advanced Client reports a full inventory upon install
The client continues to report delta inventory of changes
The client reports a delta inventory but that inventory gets "lost"
The client continues to report delta inventory but the changes in the "lost" inventory never appear in the database
The client gets resync'd, sending up a full inventory, and the changes that were "lost" now appear

Clients don't get resync'd under normal conditions therefore that inventory may not ever appear in the database. This can become an issue for inventory items such as security updates (staying applicable in the database but not applicable on the client). System Center Configuration Manager 2007 contains architectural changes which prevent this scenario from occurring. Specifically SCCM 2007 serializes software and hardware inventory reporting so that missing reports, which are based on serial numbers instead of timestamps, trigger a re-synchronization of inventory at the client.

So if you don't plan on upgrading to SCCM 2007 in the near future how might you prevent inventory from being "lost"? I documented some steps that should assist with detecting, and possibly resolving, the rare scenario when clients send up inventory that somehow disappears before getting loaded into the database. These steps are simply an example of how one might do this and the scripts are not tested and do not contain any type of error handling, logging, or reporting.

Step # 1 – Modify the SMS_DEF.MOF

Modify the Win32_OperatingSystem section of the MOF to report "LocalDateTime". This is required because the "Workstation Status" section shows "Last Hardware Scan" but there isn't a way to keep the history of this data therefore we need a consistent time we can key in on that writes to a history table.
Create a new class in the SMS_DEF.MOF to pick up a new WMI class which we'll create a populate later:

//SMSInventoryHistory
[SMS_Report(TRUE),
SMS_Group_Name("SMS Inventory"),
SMS_Class_ID("MICROSOFT|SMS_INVENTORY|1.0"),
Namespace("\\\\\\\\.\\\\root\\\\SMSINVENTORY")]
class InvHistory: SMS_Class_Template
{
[SMS_Report(TRUE),key]
datetime   ScanTime;
[SMS_Report(TRUE)]
uint32   KeyIncrement;
[SMS_Report(TRUE)]
string   ScanType;
};
Notice the KeyIncrement field. This is there because we want to report every instance of this class for every inventory. It is for this reason that we don't need history enabled for this class so it can be disabled by using KB836432 (This still applies to SMS 2003 and likely SCCM 2007).

Step # 2 – Create a recurring advertisement, which should probably run at least twice as often as hardware inventory (if not more), which runs client.vbs

Creates a new "SMSInventory" class under "root" if it doesn't exist
Gets the last hardware scan from root\ccm\invagt:InventoryActionStatus
Creates a new instance of InvHistory in the SMSInventory namespace if the hardware scan is new
If the inventory is already recorded then update the "KeyIncrement" field so SMS reports this in every delta
Cleans up any instances older than 14 days by default to keep the delta inventory from growing too large

'client.vbs
'rslaten
'08/15/2007

'Determines when to clean out old inventory instances
iDays = 14

'Connect to WMI locally
Set oLocator = CreateObject("WbemScripting.sWbemLocator")
Set oSvc = oLocator.ConnectServer(".", "root")

'Create a custom namespace to hold data if it doesn't already exist
Set oNamespaces = oSvc.InstancesOf("__namespace")
bFound = False
For each oNamespace in oNamespaces
    If oNamespace.Name = "SMSInventory" Then
        bFound = True
        Exit For
    End If
Next

If Not bFound Then
    Set oNamespace = oSvc.Get("__namespace")
    Set oCustomNameSpace = oNamespace.SpawnInstance_
    oCustomNamespace.name = "SMSInventory"
    oCustomNamespace.Put_()

    'Create a custom class to hold data
    wbemCimtypeUint32 = 19
    wbemCimtypeDatetime = 101
    wbemCimtypeString = 8
    Set oWMI = GetObject("winmgmts:root\SMSInventory")
    Set oClass = oWMI.Get()
    oClass.Path_.Class = "InvHistory"
    oClass.Properties_.add "ScanTime", wbemCimtypeDatetime
    oClass.Properties_("ScanTime").Qualifiers_.add "key", true
    oClass.Properties_.add "KeyIncrement", wbemCimtypeUint32
    oClass.Properties_.add "ScanType", wbemCimtypeString
    oClass.Put_()
End If

'Get timezone
Set oSvc = oLocator.ConnectServer(".", "root\cimv2")
Set collTimeZone = oSvc.ExecQuery("select Bias, DaylightBias from Win32_TimeZone")
For Each oTimeZone in collTimeZone
    iTimeZone = oTimeZone.Bias - oTimeZone.DaylightBias
Next

'Get last Hinv report date and convert to local time
Set oSvc = oLocator.ConnectServer(".", "root\ccm\invagt")
HActionID = """{00000000-0000-0000-0000-000000000001}"""
Set oHinv = oSvc.Get("InventoryActionStatus.InventoryActionID=" & _
    HActionID)
Const CONVERT_TO_LOCAL_TIME = true
'dLastReportDate = ConvertToGMT(oHinv.LastReportDate)
dLastReportDate = oHinv.LastReportDate
dLastReportDate = WMIDateStringToDate(dLastReportDate)
Set dNewTime = CreateObject("WbemScripting.SWbemDateTime")
dNewTime.SetVarDate dLastReportDate, CONVERT_TO_LOCAL_TIME
dLastReportDate = dNewTime.GetVarDate(CONVERT_TO_LOCAL_TIME)
dLastReportDate = DateAdd("n", iTimeZone, dLastReportDate)
dLastReportDate = GetWMIDate(dLastReportDate, "+000")

'Set last Hinv report date
Set oSvc = oLocator.ConnectServer(".", "root\SMSInventory")
Set oHinvHistory = oSvc.InstancesOf("InvHistory")

'First instance in class
If oHinvHistory.Count = 0 Then
    Set oHinv = oSvc.Get("InvHistory").SpawnInstance_
    oHinv.ScanTime = dLastReportDate
    oHinv.KeyIncrement = 0
    oHinv.ScanType = "Hardware"
    oHinv.Put_()
Else
    bFound = False
    
    'Calculate date to clean up old instances
    Set dExpire = CreateObject("WbemScripting.SWbemDateTime")
    dExpire.SetVarDate Now, CONVERT_TO_LOCAL_TIME
    dRegular = dExpire.GetVarDate(CONVERT_TO_LOCAL_TIME)
    dExpireDate = DateAdd("d", -iDays, dRegular)
    dExpire.SetVarDate dExpireDate, CONVERT_TO_LOCAL_TIME
    
    'Updating all instances
    For each oInstance in oHinvHistory
        If dLastReportDate = oInstance.ScanTime Then
            bFound = True
        End If
        
        'Clean up old instances
        If oInstance.ScanTime < dExpire Then
            oInstance.Delete_
        Else
            'Increment the KeyIncrement property to force SMS to pick
            'up the instance during inventory
            oInstance.KeyIncrement = oInstance.KeyIncrement + 1
            oInstance.Put_
        End If
    Next
    
    'Create a new instance if needed
    If Not bFound Then
        Set oHinv = oSvc.Get("InvHistory").SpawnInstance_
        oHinv.ScanTime = dLastReportDate
        oHinv.KeyIncrement = 0
        oHinv.ScanType = "Hardware"
        oHinv.Put_()    
    End If
End If

Function ConvertToGMT(dDate)
    ConvertToGMT = Replace(dDate, "-000", iTimeZone)
End Function

Function WMIDateStringToDate(dtmInstallDate)
     WMIDateStringToDate = CDate(Mid(dtmInstallDate, 5, 2) & "/" & _
     Mid(dtmInstallDate, 7, 2) & "/" & Left(dtmInstallDate, 4) _
     & " " & Mid (dtmInstallDate, 9, 2) & ":" & _
     Mid(dtmInstallDate, 11, 2) & ":" & Mid(dtmInstallDate, _
     13, 2))
End Function

Function GetWMIDate(vd,strOffset)
    On Error Resume Next
    GetWMIDate = Year(vd) & AddZero(Month(vd)) & AddZero(Day(vd)) & _
            AddZero(Hour(vd)) & AddZero(Minute(vd)) & _
            AddZero(Second(vd)) & ".000000" & strOffset
End Function

Function AddZero(pNum)
    On Error Resume Next
    If pNum <=9 then
        AddZero = "0" & pNum
    Else AddZero = pNum
    End If
End Function

Step # 3 – Periodically check to see if there is any missing hardware inventory by running server.vbs

Queries the SMS database for OS LocalDateTime and the custom SMSInventory ScanTime
Compares the ScanTime to LocalDateTime, searching for missing LocalDateTime entries. To find a match the LocalDateTime must be within 5 minutes from the ScanTime. If any clients take longer than 5 minutes to complete a hardware inventory cycle then this may need to be increased.
For any ScanTime without a matching LocalDateTime, we display the fact that there is a missing inventory.

'server.vbs
'rslaten
'08/15/2007

'Globals
Dim aClients(), iClients, iInstanceCount, iTotal

'Get SMS Namespace
sSMSNameSpace = GetSMSNameSpace()

'Connect to site server
Set oWMI = GetObject("winMgmts:" & sSMSNameSpace)

'Query clients and create and array of client objects
sQuery = "select distinct SMS_R_System.Name, SMS_R_System.SMSUniqueIdentifier," & _
    " SMS_G_System_SMS_INVENTORY.ScanTime, SMS_GH_System_OPERATING_SYSTEM.LocalDateTime" & _
    " from  SMS_R_System inner join SMS_G_System_SMS_INVENTORY on " & _
    "SMS_G_System_SMS_INVENTORY.ResourceID = SMS_R_System.ResourceId inner" & _
    " join SMS_GH_System_OPERATING_SYSTEM on " & _
    "SMS_GH_System_OPERATING_SYSTEM.ResourceID = SMS_R_System.ResourceId " & _
    "where SMS_G_System_SMS_INVENTORY.ScanTime is not NULL and " & _
    "SMS_GH_System_OPERATING_SYSTEM.LocalDateTime is not NULL"

Set aCollection = oWMI.ExecQuery(sQuery)
iTotal = aCollection.count
For Each oInstance In aCollection
    If sLastName <> oInstance.SMS_R_System.Name Then
        'Make sure this isn't the first iteration in the array
        If iInstanceCount <> 0 Then
            'Add to master array
            ReDim Preserve aClients(iClients)
            Set aClients(iClients) = oClient
            iClients = iClients + 1
        End If
        
        'Now create new client object
        Set oClient = New Client
        oClient.sClient = oInstance.SMS_R_System.Name
        oClient.sGUID = oInstance.SMS_R_System.SMSUniqueIdentifier
    End If
    
    If sLastScan <> oInstance.SMS_G_System_SMS_Inventory.ScanTime Then
        oClient.AddSMSInventoryScanDate(oInstance.SMS_G_System_SMS_Inventory.ScanTime)
    End If
    
    If sLastOSScan <> oInstance.SMS_GH_System_OPERATING_SYSTEM.LocalDateTime Then
        oClient.AddOSScanDate(oInstance.SMS_GH_System_OPERATING_SYSTEM.LocalDateTime)
    End If 

    sLastName = oInstance.SMS_R_System.Name
    sLastScan = oInstance.SMS_G_System_SMS_Inventory.ScanTime
    sLastOSScan = oInstance.SMS_GH_System_OPERATING_SYSTEM.LocalDateTime
    iInstanceCount = iInstanceCount + 1
    
    'If this is the last instance add it to the array
    If iInstanceCount = iTotal Then
        'Add to master array
        ReDim Preserve aClients(iClients)
        Set aClients(iClients) = oClient
        iClients = iClients + 1    
    End If
Next

'Loop through clients in memory to check for missing inventory
For each oClient in aClients
    aScans = oClient.aScans
    WScript.Echo "******************************************"
    WScript.Echo "Client = " & oClient.sClient
    WScript.Echo "GUID = " & oClient.sGUID
    For each oScan in oClient.aScans
        If not oScan.isOS Then
            Set oMatch = new Match
            oMatch.dScan = WMIDateStringToDate(oScan.dDate)
            oMatch.bMatch = false
            
            'Find a matching OS time (look for match within 5 minutes)
            For each oTime in aScans
                If oTime.isOS Then
                    If DateDiff("n", oMatch.dScan, _
                        WMIDateStringToDate(oTime.dDate)) < 5 and _
                        DateDiff ("n", oMatch.dScan, _
                        WMIDateStringToDate(oTime.dDate)) > -5 Then             
                        oMatch.dOS = WMIDateStringToDate(oTime.dDate)
                        oMatch.bMatch = true
                    End If
                End If
            Next
            
            'Make sure we found a match
            If not oMatch.bMatch Then
                WScript.Echo "*PROBLEM FOUND*"
                WScript.Echo "SMS Inventory Report = " & oMatch.dScan
                WScript.Echo "*NO MATCHING OS DATE FOUND*"
            Else
                WScript.Echo oMatch.dScan & " = " & oMatch.dOS
            End If
        End If
    Next
    WScript.Echo "******************************************"
Next

'Get regular date
Function WMIDateStringToDate(dtmInstallDate)
    WMIDateStringToDate = CDate(Mid(dtmInstallDate, 5, 2) & "/" & _
        Mid(dtmInstallDate, 7, 2) & "/" & Left(dtmInstallDate, 4) _
            & " " & Mid (dtmInstallDate, 9, 2) & ":" & _
                Mid(dtmInstallDate, 11, 2) & ":" & Mid(dtmInstallDate, _
                    13, 2))
End Function


'Gets SMS Namespace from local site server
Function GetSMSNameSpace()
    Set refWMI = GetObject("winMgmts:\root\sms")    
    Set colNameSpaceQuery = refWMI.ExecQuery("select * from SMS_ProviderLocation")
    For Each refitem in colNameSpaceQuery
        GetSMSNameSpace = refitem.NamespacePath
    Next
End Function

Class Client
    Public aScans()
    Private i
    Public sClient
    Public sGUID
    
    Public Sub AddOSScanDate(dScanDate)
        'Check for duplicates
        bFound = false
        For Each oScan in aScans
            If dScanDate = oScan.dDate And _
                oScan.isOS = true Then
                bFound = true
                Exit For
            End If
        Next
        
        If Not bFound Then
            Set oScan = New Scan
            oScan.dDate = dScanDate
            oScan.isOS = true
            ReDim Preserve aScans(i)
            Set aScans(i) = oScan
            i = i + 1
        End If
    End Sub
    
    Public Sub AddSMSInventoryScanDate(dScanDate)
        'Check for duplicates
        bFound = false
        For Each oScan in aScans
            If dScanDate = oScan.dDate And _
                oScan.isOS = false Then
                bFound = true
                Exit For
            End If
        Next
        
        If Not bFound Then        
            Set oScan = New Scan
            oScan.dDate = dScanDate
            oScan.isOS = false
            ReDim Preserve aScans(i)
            Set aScans(i) = oScan
            i = i + 1    
        End If
    End Sub
End Class

Class Scan
    Public dDate
    Public isOS
End Class

Class Match
    Public dScan
    Public dOS
    Public bMatch
End Class

Step # 4 – Force a resync on the clients that have "lost" inventory

The method to delete the local inventory cache is the known and documented method of doing this.
There may be a way to use the MP API to create a server side policy, but this would require significant work and a non-script (C++) application. Internally, as you can see with SQL profiler, we execute the sp_RC_InvResync stored procedure but as you know executing these directly isn't recommended or supported.

These examples do not contain error checking and need to be optimized for performance. The examples have also only been tested in a very small test environment using only the scenario documented at the top of this post. If this method is to be used in a production environment more code work and testing needs to be done, particularly on the server end, to improve the detection logic, add history to which clients resyncs have been sent to, and add reporting capabilities.

**Steps 3 and 4 might not be required. During testing I found a potentially unforeseen benefit of running the client.vbs script on clients with "lost" inventory. Since every instance of the InvHistory class is reported during every inventory, when an instance is listed as "Update" but isn't in the database, dataloader will automatically request a resync for that client. More testing of this finding needs to be done to verify that this will work, and if it does it should simplify detecting which clients have lost inventory**

Bit Fields and the SMS_Advertisement Class

rslaten — Tue, 17 Jul 2007 22:12:00 GMT

I recently worked on an issue involving a customer attempting to create a mandatory Advert using a C# application. The advertisement worked but wasn't mandatory even though it looked to be in the SMS Admin console. There was also some confusion as to how the bit field properties work and why the advert wasn't mandatory. The customer had noticed that the TimeFlags value in the SMS_Advertisement class was different in their custom application than one created by the SMS Admin Console. I sent the following explanation which I wanted to share:

Dear <customer>,

I can't debug your custom application but I did end up having to create a test application (code attached) that emulates what the <custom> application does so I could see what your instance of SMS_Advertisement looks like. After viewing the differences I saw that an advert created in the SMS Admin console, and one created with the <custom> application, were different and it wasn't just the TimeFlags property. The SMS Admin console uses the SDK just like your program so it is just a matter of seeing that there is a difference between the two classes and informing the developer of the custom application of the difference so they can correct it.

There was also some confusion over how the TimeFlags property works so I explain this below:

SMS uses bit fields for lots of on/off settings. The TimeFlags property is no exception. The TimeFlags property is a bit field, which is actually just a set of boolean flags. By default, when a regular mandatory advertisement is created through the SMS Admin console, a decimal value of 8209 is assigned to the TimeFlags property. 8209 converted to binary is "10000000010001". This is the important number.

Here is what the SDK says about the TimeFlags property:

TimeFlags
Datatype: uint32
Access type: Read-only
Qualifiers: Bits

Reserved for internal use. Duplicates the information in the time-related properties. For example, ENABLE_PRESENT is set when PresentTimeEnabled equals TRUE. Bit flags are as follows:

ENABLE_PRESENT (bit 0 = 1)
ENABLE_EXPIRATION (bit 1 = 2)
ENABLE_AVAILABLE (bit 2 = 4)
ENABLE_UNAVAILABLE (bit 3 = 8)
ENABLE_MANDATORY (bit 4 = 16)
GMT_PRESENT (bit 8 = 256)
GMT_EXPIRATION (bit 9 = 512)
GMT_AVAILABLE (bit 10 = 1024)
GMT_UNAVAILABLE (bit 11 = 2048)
GMT_MANDATORY (bit 12 = 4096)

So now we know what the real settings are. You count from right to left of the binary number ignoring the first bit. As you can see 8209 really means ENABLE_MANDATORY. In the case of 8193 (10000000000001) none of the bits are on. I wrote a test application that emulates what the <custom> program does (I couldn't view the differences between an advert created by the console and one by their application without doing this) and also created a test mandatory advert using the SMS admin console. I compared the potentially relevant differences and those are noted below:

AdvertFlags Property:
<customer> App. is set to 67108864 (100000000000000000000000000)
Admin Console is set to 0
*This shouldn't matter since none of the flags are enabled anyway

AssignedScheduleEnabled Property:
<custom> App. is set to False
Admin Console is set to True
Per SDK: Indicates whether the schedule defined in AssignedSchedule is active. The default value is FALSE.

I changed the test application by setting the AssignedScheduleEnabled property and it started working and the TimeFlags property was now set to ENABLE_MANDATORY. Basically, the problem appears to be that the advertisement created with the <custom> program isn't ever being set to mandatory.

Thanks,

Russ

Here is the code in the test application that I wrote to emulate what the customer was doing:

using System;
using System.Collections.Generic;
using System.Text;
using Microsoft.SystemsManagementServer.Automation;

namespace CreateAdvert
{
    class Program
    {
        static void Main(string[] args)
        {
            SMSProvider oProvider = new SMSProvider("server", "administrator", "password");
            SMSPackage oPackage = oProvider.Packages.Get("CEN00001");
            SMSProgram oProgram = oPackage.Programs.Create("Notepad", "notepad.exe");
            oProgram.AllowUserToInteractWithProgram = true;
            oProgram.RunMode = ProgramRunModes.Normal;
            oProgram.RunOnAnyPlatform = true;
            oProgram.UserRequirements = UserRequirementsFlags.OnlyRunWhenUserLoggedOn;
            oProgram.Save();
            SMSCollection oCollection = oProvider.Collections.Get("SMS00001");
            SMSAdvertisement oAdvert = oProvider.Advertisements.Create("Test", oCollection, oProgram);

            oAdvert.Comment = "Test";
            oAdvert.PresentTimeEnabled = true;
            DateTime now = DateTime.Now;
            oAdvert.PresentTime = now;
            DateTime tomorrow = DateTime.Now.AddDays(1);
            oAdvert.IncludeSubCollections = false;
            oAdvert.MandatoryOverSlowLinks = true;
            oAdvert.WhenLocalDPAvailable = LocalDPOptions.DownloadFromDistributionPoint;
            oAdvert.AssignedScheduleEnabled = true; //this is what was missing

            DateTime dtTenMin = DateTime.Now.AddMinutes(10);
            SMSScheduleToken_NonRecurring tokNonRec = new SMSScheduleToken_NonRecurring(new DateTime(dtTenMin.Year, dtTenMin.Month, dtTenMin.Day, dtTenMin.Hour, dtTenMin.Minute, dtTenMin.Second));
            oAdvert.AssignedSchedules.Add(tokNonRec);
            DateTime later = DateTime.Now.AddYears(1);
            oAdvert.ExpirationTime = new DateTime(later.Date.Year, later.Date.Month, later.Date.Day, 5, 0, 0);

            oAdvert.Save();
        }
    }
}

Finding Overlapping Boundaries in SMS (SMSBoundaries v1.42)

rslaten — Tue, 20 Mar 2007 18:13:00 GMT

Have you ever found yourself in a situation where an SMS Advanced client ends up getting policy or advertisements from the wrong site, or they are using the wrong MP/DP? This is a very common issue for our customers and determining root cause can be difficult. When AD Sites and IP Ranges were included in SMS 2003 overlapping boundary issues became much more common and much harder to control. In many larger environments the administrator managing SMS is not responsible for managing AD sites causing even more confusion.

Back in early 2005 I wrote an executable called SMSBoundaries.exe that is used to troubleshoot such issues. SMSBoundaries.exe would query AD and convert all subnets specified in any SMS AD Site boundary to IP ranges. It would then convert those ranges to integer format and look for overlaps between all boundaries. This tool is still widely used by Microsoft support but it has several flaws. One of the flaws is that it won't find overlapping situations due to orphaned data left in AD, or data from a separate hierarchy. Another flaw is that it couldn't really find all the possible overlaps if SMS Subnets were specified because it didn't know the subnet mask of the clients (hence it couldn't really derive the appropriate IP Range to use for comparison).

Despite these flaws I intended to make sure this tool was included in the next release of the toolkit (then toolkit3). Obviously this toolkit never came out therefore the tool remained for use by only Microsoft support to help solve issues related to overlapping boundaries.

Over the years I've been asked to convert this tool to vbscript. The reason for doing this is because it's easier to include in other tools support uses to troubleshoot SMS (like the new version of MPSReports that support uses to collect technical data to diagnose customer issues) and it's easier to get in more people's hands.

Back in October 2006 I converted the tool to vbscript and added the missing functionality to the new tool. I have since added a few more things with the help of Jeff Tondt from Microsoft Consulting Services. This script is intended to be an example demonstrating how to find overlapping SMS boundaries in your environment. Like the rest of the examples on this blog this script is not supported. Here is a description of this script:

Syntax:

Cscript.exe smsboundaries.vbs verbose <clientname>

The verbose and <clientname> parameters are both optional.

The output of the script is an XML and Log file created in the same directory where the tool is run. The tool should be run on the SMS Central Site using an account that has rights to the SMS Central site, AD, and the client if one is specified on the command line. The XML file should be used for general viewing and the log file should be used when troubleshooting an issue with the script, viewing which boundaries are overlapping in the case where you have many overlapping boundaries, or when looking to see what sites a client specified on the command line falls under.

How it works:

Gets Command Line arguments
Starts logging to SMSBoundaries.log (In SMS Logging format so SMS Trace can be used to view the log).
Gets the site boundaries of all sites in the hierarchy by querying the SMS Central Site database through the SMS WMI SDK provider. Each boundary is stored in an array of Boundary objects. For the IP Ranges the script automatically converts the range to an integer IP Range which is later used to find overlapping boundaries.
If any SMS Subnets are configured the script gets the IP subnet information for every client that reports up through this hierarchy.
For every SMS Subnet specified, the script finds the first client that falls in this subnet and creates a new Boundary object using the client IP information gathered previously. The script will create additional client Boundary objects for any clients that fall within that subnet but have a different range (so they have a different subnet mask). This process is important otherwise the script couldn't identify all possible overlapping conditions. Of course this is also dependant on having clients that meet this condition in inventory. If you can think of a better way of doing this please let me know.
Use a simple LDAP query to get all the AD sites specified in the mSSMSSiteBoundaries and mSSMSRoamingBoundaryRange namespaces and create a new Boundary object for each.
Create new Boundary objects for each AD Subnet found (by using another LDAP query to get the subnets) that is associated with an AD Site found in either SMS or AD.
Sort the array of Boundary objects by site code.
Find overlapping boundaries by looking for explicit boundary matches for AD site names or IP Subnets specified in SMS.
Find overlapping boundaries by looking for any overlapping integer IP ranges of which we have for every type of boundary.
Mark any Boundary object found to be overlapping as such.
Dump all boundaries to a log and XML file.
Connect to the client if specified and determine what sites the client falls under.

Things to consider:

Boundary objects are created where they are found. What this means is that it may appear you have duplicate boundary objects. For instance, an AD Site Boundary specified in one SMS site under both the "Roaming Boundaries" and "Site Boundaries" sections will generate at least 5 boundary objects. None of these will appear overlapping but can cause confusion. This occurs because the boundary is found in two places in SMS (one legacy boundary and one roaming boundary), two places in AD (one legacy boundary and one roaming boundary), and at least one additional boundary for any subnets that are linked to the AD Site.
The old SMSBoundaries.exe used a nicely formatted log file to display the output. The SMSBoundaries script uses a nicely formatted xml file and poorly formatted log file. Many people have requested either a better log file or output to a csv file. I'm glad I converted this to vbscript so someone else can do this . It's on my list of things to do but it's a low priority. If anyone can comment on how to easily convert the XML to a nicely formatted spreadsheet please do (I know Office 2007 has some options for this).
If a client is specified on the command line that information won't be written to the XML, you have to view the log file. This is really only useful if you're troubleshooting a specific client or site.
Verbose logging is helpful if you think you've found an issue with the script.
If you have any SMS Subnets specified in any of the sites in your hierarchy then the script will query the IP information for every client in the hierarchy. In large hierarchies (50k + clients) the script may run for over an hour because of this.
If you have lots of overlapping boundaries the best way to figure out which boundary is overlapping it is to use the log. Just search for the boundary range or subnet that is listed as overlapping in the XML and if you're in the overlapping section of the log it will show you the boundary that it found which overlapped it.

*This is an example of how to find overlapping boundaries in your environment. If you find any issues with this example or can think of additional functionality which should be added please comment on this blog entry. If any updates to this example are needed I will upload the script changes to this blog entry and update the version number in the title.*

Submitting software inventory records to an SMS 2003 MP using the MP API

rslaten — Mon, 03 Jul 2006 20:48:00 GMT

There are several supported ways to add data to the SMS database but they typically come from an SMS 2003 advanced client. If you want to add data to an existing client without having to make the agent on the client send it up, or add data to the database for a non-SMS client, then you can use the MP API.

The SMS SDK contains documentation and some sample code for submitting data via the MP API. There are some other things you'll need to do in order to get the MP API working with SMS 2003 SP1 and above.

Below is an example of using the MP API to submit software inventory data to a Management Point. This data gets converted from XML to a SIC by the MP, then moved to the site server, and finally loaded into the database. Keep in mind that the software inventory data I'm loading into the database in this example is the minimum so much more can be added. Also, you can create your own GUIDs using CoCreateGUID().

Here are some tips when developing/testing submitting discovery data using the MP API.
- Enable verbose and debug logging on the SMS 2003 Management Point you're working with.
- Have an SMS 2003 advanced client already submitting data to this MP.
- Turn on report archival on the advanced client so you can see what a properly formatted XML looks like.
- View the following logs in this order: IIS logs (shows IIS handling the message), ccmisapi.log (SMS ISAPI filter), MP_Sinv.log (converts the XML to a SIC), mpfdm.log (moves the SIC from the MP to site server), and sinvproc.log (loads the SIC into the database).
- Make sure you've installed the hotfix from KB917873 onto your SDK. This article is not published as of 07/03/2006 but the hotfix is still available by calling Microsoft support.
- Don't forget to set the Byte Order Mark in your XML attachment.
- Make sure you call SetClientID, which is only usable if you've included the .h/.c files from KB917873 in your project.
- If the program fails when running on the MP with http:// in front of the MP Name, try running it without the http:// (this goes through COM instead of IIS).
- Run the DDRExample program first to create a discovery record in the database prior to using this application

//MPAPI-SinvExample.cpp : Defines the entry point for the console application.
//Rslaten 07/2006

#include "stdafx.h"
#include "MPAPI-SinvExample.h"
#include "SmsMsgAPI.h"
#include "SmsMsgAPI_i.c"
#include "strsafe.h"
#ifdef _DEBUG
#define new DEBUG_NEW
#endif

#define MAX_BUFFER_LENGTH 0x1000

CWinApp theApp;

using namespace std;

//  Macros to perform error handling and make the code cleaner.
#define _BEGIN \
    HRESULT __hrRetVal = S_OK; \
    { \
 
#define _END \
    } \
    __End: \
 
#define _RETVAL __hrRetVal
 
#define _CHECKHR(expr) if(FAILED(expr)) { __hrRetVal=expr; goto __End; }

int wmain( int argc, wchar_t *argv[], wchar_t *envp[] )
{
	int nRetCode = 0;

	// initialize MFC and print and error on failure
	if (!AfxWinInit(::GetModuleHandle(NULL), NULL, ::GetCommandLine(), 0))
	{
		// TODO: change error code to suit your needs
		_tprintf(_T("Fatal Error: MFC initialization failed\n"));
		nRetCode = 1;
	}
	else
	{
		if (argc < 2)
		{
			printf("Usage:MPAPI-HinvExample.exe <http://mpname>\n");
		}
		else
		{
			static WCHAR SINVBody[MAX_BUFFER_LENGTH];
			static WCHAR SINVAttach[MAX_BUFFER_LENGTH];
			ISmsMessaging               *pMessaging = NULL;
			ISmsMessage                 *pRequest = NULL;
			ISmsMessage                 *pReply = NULL;
			ISmsMessage2				*pRequest2 = NULL;
			WCHAR                       *pszRequestMessage = NULL;
			WCHAR                       *pszReplyMessage = NULL;
			WCHAR						*sMPName = NULL;
			WCHAR						*pszTrackingID = NULL;
			LPCWSTR						sClientID = NULL;
			LPCWSTR						sReportID = NULL;
			LPCWSTR						sEndPoint = NULL;

			//Set variables
			sReportID = L"{00000000-0000-0000-0000-000000000002}";
			sEndPoint = L"MP_SinvEndpoint";
			sClientID = L"GUID:8081C07C-4674-48E4-A525-5CAD419A4EB3";
			sMPName = argv[1];

			CoInitialize(NULL);

			//Build Report Header for Hinv
                   wcscat(SINVBody,L"<ReportHeader>");
                   wcscat(SINVBody,L"<Identification>");
                   wcscat(SINVBody,L"<Machine>");
                   wcscat(SINVBody,L"<ClientID>GUID:8081C07C-4674-48E4-A525-5CAD419A4EB3</ClientID>");
                   wcscat(SINVBody,L"</Machine>");
                   wcscat(SINVBody,L"</Identification>");
                   wcscat(SINVBody,L"</ReportHeader>");
			//Build Message Attachment for Hinv
                   SINVAttach[0] = 0xFEFF; //Add BOM
                   wcscat(SINVAttach,L"<Report>");
                   wcscat(SINVAttach,L"<ReportHeader>");
                   wcscat(SINVAttach,L"<Identification>");
                   wcscat(SINVAttach,L"<Machine>");
                   wcscat(SINVAttach,L"<ClientInstalled>1</ClientInstalled>");
                   wcscat(SINVAttach,L"<ClientType>1</ClientType>");
                   wcscat(SINVAttach,L"<ClientID>GUID:8081C07C-4674-48E4-A525-5CAD419A4EB3</ClientID>");
                   wcscat(SINVAttach,L"<ClientVersion>1.0</ClientVersion>");
                   wcscat(SINVAttach,L"<NetBIOSName>MPAPITestClient</NetBIOSName>");
                   wcscat(SINVAttach,L"<CodePage>437</CodePage>");
                   wcscat(SINVAttach,L"<SystemDefaultLCID>1033</SystemDefaultLCID>");
                   wcscat(SINVAttach,L"</Machine>");
                   wcscat(SINVAttach,L"</Identification>");
                   wcscat(SINVAttach,L"<ReportDetails>");
                   wcscat(SINVAttach,L"<ReportContent>Inventory\\x0020Data</ReportContent>");
                   wcscat(SINVAttach,L"<ReportType>Full</ReportType>");
                   wcscat(SINVAttach,L"<Date>20060120124946.000000-360</Date>");
                   wcscat(SINVAttach,L"<Version>1.3</Version>");
                   wcscat(SINVAttach,L"<Format>1.0</Format>");
                   wcscat(SINVAttach,L"</ReportDetails>");
                   wcscat(SINVAttach,L"<InventoryAction ActionType=\"Predefined\">");
    wcscat(SINVAttach,L"<InventoryActionID>{00000000-0000-0000-0000-000000000002}</InventoryActionID>");
                   wcscat(SINVAttach,L"<Description>Software</Description>");
    wcscat(SINVAttach,L"<InventoryActionLastUpdateTime>20050913162140.000000+000</InventoryActionLastUpdateTime>");
                   wcscat(SINVAttach,L"</InventoryAction>");
                   wcscat(SINVAttach,L"</ReportHeader>");
                   wcscat(SINVAttach,L"<ReportBody>");
                   wcscat(SINVAttach,L"<Instance ParentClass=\"FileSystemFile\" Class=\"FileSystemFile\"");
                   wcscat(SINVAttach,L" Namespace=\"\\\\MPAPITestClient\\ROOT\\ccm\\invagt\\\" Content=\"New\">");
                   wcscat(SINVAttach,L"<FileSystemFile>");
                   wcscat(SINVAttach,L"<CompanyName>Microsoft\\x0020Corporation</CompanyName>");
                   wcscat(SINVAttach,L"<FileDescription>Notepad</FileDescription>");
                   wcscat(SINVAttach,L"<FileVersion>5.1.2600.2180\\x0020(xpsp_sp2_rtm.040803-2158)</FileVersion>");
                   wcscat(SINVAttach,L"<LastWriteDate>20040804060000.000000+***</LastWriteDate>");
                   wcscat(SINVAttach,L"<Name>notepad.exe</Name>");
                   wcscat(SINVAttach,L"<Path>C:\\\\WINDOWS\\\\system32\\\\</Path>");
                   wcscat(SINVAttach,L"<ProductLanguage>1033</ProductLanguage>");
    wcscat(SINVAttach,L"<ProductName>Microsoft&#174;\\x0020Windows&#174;\\x0020Operating\\x0020System</ProductName>");
                   wcscat(SINVAttach,L"<ProductVersion>5.1.2600.2180</ProductVersion>");
                   wcscat(SINVAttach,L"<Size>69120</Size>");
                   wcscat(SINVAttach,L"</FileSystemFile>");
                   wcscat(SINVAttach,L"</Instance>");
                   wcscat(SINVAttach,L"</ReportBody>");
                   wcscat(SINVAttach,L"</Report>");
		_BEGIN

			//Create root messaging object
			_CHECKHR( ::CoCreateInstance(
                        CLSID_SmsMessaging,
                        NULL,
                        CLSCTX_INPROC,
                        IID_ISmsMessaging,
                        (LPVOID*)&pMessaging) );

			//Create message object for request
			_CHECKHR( pMessaging->CreateMessage(&pRequest) );

			//Use the SetClientID method (must have .c/.h files from KB917873)
			_CHECKHR( pRequest->QueryInterface(IID_ISmsMessage2, (void **) &pRequest2) );
			_CHECKHR( pRequest2->SetClientID(sClientID) );

			//Set Body (Header)
			_CHECKHR( pRequest2->SetBodyFromString(SINVBody) );

			//Get length of attachment
			size_t pcch;
			StringCchLengthW(SINVAttach,MAX_BUFFER_LENGTH,&pcch);
			ULONG uSize = pcch * 2;

			//Set Attachment
			_CHECKHR( pRequest2->SetAttachmentFromBuffer(
                        sReportID,
                        (const BYTE*)SINVAttach,
                        uSize) );
			
			//Set EndPoint
			_CHECKHR( pRequest2->SetTargetEndpoint(sEndPoint) );

			//Post Message
			_CHECKHR( pMessaging->Post(sMPName, pRequest2, &pszTrackingID) );

		_END

			printf("\n\n%s%X", "Return Code=", __hrRetVal);

			if(pszTrackingID)
			{
				::CoTaskMemFree(pszTrackingID);
			}
			return S_OK;

			pRequest2->Release();
		}
	}
	CoUninitialize();
	return nRetCode;
}

Submitting hardware inventory records to an SMS 2003 MP using the MP API

rslaten — Fri, 30 Jun 2006 01:23:00 GMT

Below is an example of using the MP API to submit hardware inventory data to a Management Point. This data gets converted from XML to a MIF by the MP, then moved to the site server, and finally loaded into the database. Keep in mind that the hardware inventory data I'm loading into the database in this example is the minimum so much more can be added. Also, you can create your own GUIDs using CoCreateGUID().

Here are some tips when developing/testing submitting discovery data using the MP API.
- Enable verbose and debug logging on the SMS 2003 Management Point you're working with.
- Have an SMS 2003 advanced client already submitting data to this MP.
- Turn on report archival on the advanced client so you can see what a properly formatted XML looks like.
- View the following logs in this order: IIS logs (shows IIS handling the message), ccmisapi.log (SMS ISAPI filter), MP_Hinv.log (converts the XML to a MIF), mpfdm.log (moves the MIF from the MP to site server), and dataldr.log (loads the MIF into the database).
- Make sure you've installed the hotfix from KB917873 onto your SDK. This article is not published as of 06/29/2006 but the hotfix is still available by calling Microsoft support.
- Don't forget to set the Byte Order Mark in your XML attachment.
- Make sure you call SetClientID, which is only usable if you've included the .h/.c files from KB917873 in your project.
- If the program fails when running on the MP with http:// in front of the MP Name, try running it without the http:// (this goes through COM instead of IIS).
- Run the DDRExample program first to create a discovery record in the database prior to using this application

// MPAPI-HinvExample.cpp : Defines the entry point for the console application.
// Rslaten 06/2006

#include "stdafx.h"
#include "MPAPI-HinvExample.h"
#include "SmsMsgAPI.h"
#include "SmsMsgAPI_i.c"
#include "strsafe.h"

#ifdef _DEBUG
#define new DEBUG_NEW
#endif

#define MAX_BUFFER_LENGTH 0x1000

CWinApp theApp;

using namespace std;

//  Macros to perform error handling and make the code cleaner.
#define _BEGIN \
    HRESULT __hrRetVal = S_OK; \
    { \
 
#define _END \
    } \
    __End: \
 
#define _RETVAL __hrRetVal
 
#define _CHECKHR(expr) if(FAILED(expr)) { __hrRetVal=expr; goto __End; }

//Main
int wmain( int argc, wchar_t *argv[], wchar_t *envp[] )
{
	int nRetCode = 0;

	// initialize MFC and print and error on failure
	if (!AfxWinInit(::GetModuleHandle(NULL), NULL, ::GetCommandLine(), 0))
	{
		// TODO: change error code to suit your needs
		_tprintf(_T("Fatal Error: MFC initialization failed\n"));
		nRetCode = 1;
	}
	else
	{
		if (argc < 3)
		{
			printf("Usage:MPAPI-HinvExample.exe <http://mpname> <sitecode>\n");
		}
		else
		{
			static WCHAR HINVBody[MAX_BUFFER_LENGTH];
			static WCHAR HINVAttach[MAX_BUFFER_LENGTH];
			ISmsMessaging               *pMessaging = NULL;
                   ISmsMessage                 *pRequest = NULL;
                   ISmsMessage                 *pReply = NULL;
			ISmsMessage2				*pRequest2 = NULL;
                   WCHAR                       *pszRequestMessage = NULL;
                   WCHAR                       *pszReplyMessage = NULL;
			WCHAR						*sMPName = NULL;
			WCHAR						*sSiteCode = NULL;
			WCHAR						*pszTrackingID = NULL;
			LPCWSTR						sClientID = NULL;
			LPCWSTR						sReportID = NULL;
			LPCWSTR						sEndPoint = NULL;

			//Set variables
			sReportID = L"{00000000-0000-0000-0000-000000000001}";
			sEndPoint = L"MP_HinvEndpoint";
			sClientID = L"GUID:8081C07C-4674-48E4-A525-5CAD419A4EB3";
			sMPName = argv[1];
			sSiteCode = argv[2]; //Not used

			CoInitialize(NULL);

                   //Build Report Header for Hinv
                   wcscat(HINVBody,L"<ReportHeader>");
                   wcscat(HINVBody,L"<Identification>");
                   wcscat(HINVBody,L"<Machine>");
                   wcscat(HINVBody,L"<ClientID>GUID:8081C07C-4674-48E4-A525-5CAD419A4EB3</ClientID>");
                   wcscat(HINVBody,L"</Machine>");
                   wcscat(HINVBody,L"</Identification>");
                   wcscat(HINVBody,L"</ReportHeader>");                 

                   //Build Message Attachment for Hinv
                   HINVAttach[0] = 0xFEFF; //Add BOM
                   wcscat(HINVAttach,L"<Report>");
                   wcscat(HINVAttach,L"<ReportHeader>");
                   wcscat(HINVAttach,L"<Identification>");
                   wcscat(HINVAttach,L"<Machine>");
                   wcscat(HINVAttach,L"<ClientInstalled>1</ClientInstalled>");
                   wcscat(HINVAttach,L"<ClientType>1</ClientType>");
                   wcscat(HINVAttach,L"<ClientID>GUID:8081C07C-4674-48E4-A525-5CAD419A4EB3</ClientID>");
                   wcscat(HINVAttach,L"<ClientVersion>1.0</ClientVersion>");
                   wcscat(HINVAttach,L"<NetBIOSName>MPAPITestClient</NetBIOSName>");
                   wcscat(HINVAttach,L"<CodePage>437</CodePage>");
                   wcscat(HINVAttach,L"<SystemDefaultLCID>1033</SystemDefaultLCID>");
                   wcscat(HINVAttach,L"</Machine>");
                   wcscat(HINVAttach,L"</Identification>");
                   wcscat(HINVAttach,L"<ReportDetails>");
                   wcscat(HINVAttach,L"<ReportContent>Inventory\\x0020Data</ReportContent>");
                   wcscat(HINVAttach,L"<ReportType>Full</ReportType>");
                   wcscat(HINVAttach,L"<Date>20060120124946.000000-360</Date>");
                   wcscat(HINVAttach,L"<Version>1.3</Version>");
                   wcscat(HINVAttach,L"<Format>1.0</Format>");
                   wcscat(HINVAttach,L"</ReportDetails>");
                   wcscat(HINVAttach,L"<InventoryAction ActionType=\"Predefined\">");
                   wcscat(HINVAttach,L"<InventoryActionID>{00000000-0000-0000-0000-000000000001}</InventoryActionID>");
                   wcscat(HINVAttach,L"<Description>Hardware</Description>");
                   wcscat(HINVAttach,L"<InventoryActionLastUpdateTime>20050913162140.000000+000</InventoryActionLastUpdateTime>");
                   wcscat(HINVAttach,L"</InventoryAction>");
                   wcscat(HINVAttach,L"</ReportHeader>");
                   wcscat(HINVAttach,L"<ReportBody>");
                   wcscat(HINVAttach,L"<Instance ParentClass=\"CCM_System\" Class=\"CCM_System\" Namespace=\"\\\\MPAPITestClient");
                   wcscat(HINVAttach,L"//root//ccm//invagt/" Content=\"New\">");
                   wcscat(HINVAttach,L"<CCM_System>");
                   wcscat(HINVAttach,L"<Domain>MPAPITestDOM.com</Domain>");
                   wcscat(HINVAttach,L"<LocalDateTime>20060120124932.664000-360</LocalDateTime>");
                   wcscat(HINVAttach,L"<Name>MPAPITestClient</Name>");
                   wcscat(HINVAttach,L"<SMSID>GUID:8081C07C-4674-48E4-A525-5CAD419A4EB3</SMSID>");
                   wcscat(HINVAttach,L"<SystemRole>Workstation</SystemRole>");
                   wcscat(HINVAttach,L"<SystemType>X86-based\\x0020PC</SystemType>");
                   wcscat(HINVAttach,L"</CCM_System>");
                   wcscat(HINVAttach,L"</Instance>");
                   wcscat(HINVAttach,L"</ReportBody>");
                   wcscat(HINVAttach,L"</Report>");
		_BEGIN

                   //Create root messaging object
                   _CHECKHR( ::CoCreateInstance(
                        CLSID_SmsMessaging,
                        NULL,
                        CLSCTX_INPROC,
                        IID_ISmsMessaging,
                        (LPVOID*)&pMessaging) );

                   //Create message object for request
                   _CHECKHR( pMessaging->CreateMessage(&pRequest) );

			//Use the SetClientID method (must have .c/.h files from KB917873)
			_CHECKHR( pRequest->QueryInterface(IID_ISmsMessage2, (void **) &pRequest2) );
			_CHECKHR( pRequest2->SetClientID(sClientID) );

			//Set Body (Header)
			_CHECKHR( pRequest2->SetBodyFromString(HINVBody) );

			//Get length of attachment
			size_t pcch;
			StringCchLengthW(HINVAttach,MAX_BUFFER_LENGTH,&pcch);
			ULONG uSize = pcch * 2;

			//Set Attachment
			_CHECKHR( pRequest2->SetAttachmentFromBuffer(
                        sReportID,
                        (const BYTE*)HINVAttach,
                        uSize) );
			
			//Set EndPoint
			_CHECKHR( pRequest2->SetTargetEndpoint(sEndPoint) );

			//Post Message
			_CHECKHR( pMessaging->Post(sMPName, pRequest2, &pszTrackingID) );

		_END

			printf("\n\n%s%X", "Return Code=", __hrRetVal);

			if(pszTrackingID)
			{
				::CoTaskMemFree(pszTrackingID);
			}
			return S_OK;

			pRequest2->Release();

		}
	}
	CoUninitialize();
	return nRetCode;
}

Submitting discovery records to an SMS 2003 MP using the MP API

rslaten — Wed, 28 Jun 2006 22:35:00 GMT

Below is an example of using the MP API to submit discovery data to a Management Point. This data gets converted from XML to a DDR by the MP, then moved to the site server, and finally loaded into the database. Keep in mind that the discovery data I'm loading into the database in this example is the minimum so much more can be added. Also, you can create your own GUIDs using CoCreateGUID().

Here are some tips when developing/testing submitting discovery data using the MP API.
- Enable verbose and debug logging on the SMS 2003 Management Point you're working with.
- Have an SMS 2003 advanced client already submitting data to this MP.
- Turn on report archival on the advanced client so you can see what a properly formatted XML looks like.
- View the following logs in this order: IIS logs (shows IIS handling the message), ccmisapi.log (SMS ISAPI filter), MP_Ddr.log (converts the XML to a DDR), mpfdm.log (moves the DDR from the MP to site server), and ddm.log (loads the DDR into the database).
- Make sure you've installed the hotfix from KB917873 onto your SDK. This article is not published as of 06/28/2006 but the hotfix is still available by calling Microsoft support.
- Don't forget to set the Byte Order Mark in your XML attachment.
- Make sure you call SetClientID, which is only usable if you've included the .h/.c files from KB917873 in your project.
- If the program fails when running on the MP with http:// in front of the MP Name, try running it without the http:// (this goes through COM instead of IIS).

// DDRExample.cpp : Defines the entry point for the console application.
// Example of how to submit discovery data using the MP API
// This is a standard C++ Win32 console application created
// using the wizard in Visual Studio and adding MFC support
// Rslaten 06/2006

#include "stdafx.h"
#include "DDRExample.h"
#include "SmsMsgAPI.h"
#include "SmsMsgAPI_i.c"
#include "strsafe.h"

#ifdef _DEBUG
#define new DEBUG_NEW
#endif

#define MAX_BUFFER_LENGTH 0x1000

CWinApp theApp;

using namespace std;

//  Macros to perform error handling and make the code cleaner.
#define _BEGIN \
    HRESULT __hrRetVal = S_OK; \
    { \
 
#define _END \
    } \
    __End: \
 
#define _RETVAL __hrRetVal
 
#define _CHECKHR(expr) if(FAILED(expr)) { __hrRetVal=expr; goto __End; }

//Main
int wmain( int argc, wchar_t *argv[], wchar_t *envp[] )
{
        int nRetCode = 0;

	// initialize MFC and print and error on failure
	if (!AfxWinInit(::GetModuleHandle(NULL), NULL, ::GetCommandLine(), 0))
	{
		_tprintf(_T("Fatal Error: MFC initialization failed\n"));
		nRetCode = 1;
	}
	else
	{
		if (argc < 3)
		{
                        printf("Usage:DDRExample.exe <http://mpname> <sitecode> \n");
		}
		else
		{
                        static WCHAR DDRBody[MAX_BUFFER_LENGTH];
                        static WCHAR DDRAttach[MAX_BUFFER_LENGTH];
                        ISmsMessaging *pMessaging = NULL;
                        ISmsMessage *pRequest = NULL;
                        ISmsMessage *pReply = NULL;
                        ISmsMessage2 *pRequest2 = NULL;
                        WCHAR *pszRequestMessage = NULL;
                        WCHAR *pszReplyMessage = NULL;
                        WCHAR *sMPName = NULL;
                        WCHAR *sSiteCode = NULL;
                        LPCWSTR sClientID = NULL;
                        LPCWSTR sReportID = NULL;
                        LPCWSTR sEndPoint = NULL;
                        WCHAR *pszTrackingID = NULL;
			
                        //Set variables
                        sReportID = L"{00000000-0000-0000-0000-000000000003}";
                        sEndPoint = L"MP_DdrEndpoint";
                        sClientID = L"GUID:8081C07C-4674-48E4-A525-5CAD419A4EB3";
                        sMPName = argv[1];
                        sSiteCode = argv[2];
               
                        CoInitialize(NULL);

                        //Build Report Header for DDR
                        wcscat(DDRBody,L"<ReportHeader>");
                        wcscat(DDRBody,L"<Identification>");
                        wcscat(DDRBody,L"<Machine>");
                        wcscat(DDRBody,L"<ClientID>GUID:8081C07C-4674-48E4-A525-5CAD419A4EB3</ClientID>");
                        wcscat(DDRBody,L"</Machine>");
                        wcscat(DDRBody,L"</Identification>");
                        wcscat(DDRBody,L"</ReportHeader>");
   
   //Build Message Attachment for DDR
   DDRAttach[0] = 0xFEFF; //Add BOM (This is very important)
   wcscat(DDRAttach,L"<?xml version='1.0' encoding='UTF-16'?>");
   wcscat(DDRAttach,L"<Report>");
   wcscat(DDRAttach,L"<ReportHeader>");
   wcscat(DDRAttach,L"<Identification>");
   wcscat(DDRAttach,L"<Machine>");
   wcscat(DDRAttach,L"<ClientInstalled>1</ClientInstalled>");
   wcscat(DDRAttach,L"<ClientType>1</ClientType>");
   wcscat(DDRAttach,L"<ClientID>GUID:8081C07C-4674-48E4-A525-5CAD419A4EB3</ClientID>");
   wcscat(DDRAttach,L"<ClientVersion>1.0</ClientVersion>");
   wcscat(DDRAttach,L"<NetBIOSName>MPAPITestClient</NetBIOSName>");
   wcscat(DDRAttach,L"<CodePage>437</CodePage>");
   wcscat(DDRAttach,L"<SystemDefaultLCID>1033</SystemDefaultLCID>");
   wcscat(DDRAttach,L"</Machine>");
   wcscat(DDRAttach,L"</Identification>");
   wcscat(DDRAttach,L"<ReportDetails>");
   wcscat(DDRAttach,L"<ReportContent>Inventory\\x0020Data</ReportContent>");
   wcscat(DDRAttach,L"<ReportType>Full</ReportType>");
   wcscat(DDRAttach,L"<Date>20060123125307.000000+000</Date>");
   wcscat(DDRAttach,L"<Version>6.0</Version>");
   wcscat(DDRAttach,L"<Format>1.0</Format>");
   wcscat(DDRAttach,L"</ReportDetails>");
   wcscat(DDRAttach,L"<InventoryAction ActionType=\"Predefined\">");
   wcscat(DDRAttach,L"<InventoryActionID>{00000000-0000-0000-0000-000000000003}</InventoryActionID>");
   wcscat(DDRAttach,L"<Description>Discovery</Description>");
   wcscat(DDRAttach,L"<InventoryActionLastUpdateTime>20050913162047.000000+000</InventoryActionLastUpdateTime>");
   wcscat(DDRAttach,L"</InventoryAction>");
   wcscat(DDRAttach,L"</ReportHeader>");
   wcscat(DDRAttach,L"<ReportBody>");
   wcscat(DDRAttach,L"<Instance ParentClass=\"SMS_Authority\" Class=\"SMS_Authority\" Namespace=");
   wcscat(DDRAttach,L"\"\\\\MPAPITestClient\\ROOT\\ccm\" Content=\"New\">");
   wcscat(DDRAttach,L"<SMS_Authority>");
   wcscat(DDRAttach,L"<Name>SMS:");
   wcscat(DDRAttach, sSiteCode);
   wcscat(DDRAttach, L"</Name>");
   wcscat(DDRAttach,L"</SMS_Authority>");
   wcscat(DDRAttach,L"</Instance>");
   wcscat(DDRAttach,L"</ReportBody>");
   wcscat(DDRAttach,L"</Report>");
		_BEGIN

                   //Create root messaging object
                   _CHECKHR( ::CoCreateInstance(
                        CLSID_SmsMessaging,
                        NULL,
                        CLSCTX_INPROC,
                        IID_ISmsMessaging,
                        (LPVOID*)&pMessaging) );

                   //Create message object for request
                   _CHECKHR( pMessaging->CreateMessage(&pRequest) );

			//Use the SetClientID method (must have .c/.h files from KB917873)
			_CHECKHR( pRequest->QueryInterface(IID_ISmsMessage2, (void **) &pRequest2) );
			_CHECKHR( pRequest2->SetClientID(sClientID) );

			//Set Body (Header)
			_CHECKHR( pRequest2->SetBodyFromString(DDRBody) );

			//Get length of attachment
			size_t pcch;
			StringCchLengthW(DDRAttach,MAX_BUFFER_LENGTH,&pcch);
			ULONG uSize = pcch * 2;

			//Set Attachment
			_CHECKHR( pRequest2->SetAttachmentFromBuffer(
                        sReportID,
                        (const BYTE*)DDRAttach,
                        uSize) );
			
			//Set EndPoint
			_CHECKHR( pRequest2->SetTargetEndpoint(sEndPoint) );

			//Post Message
			_CHECKHR( pMessaging->Post(sMPName, pRequest2, &pszTrackingID) );

		_END

			printf("\n\n%s%X", "Return Code=", __hrRetVal);

			if(pszTrackingID)
			{
				::CoTaskMemFree(pszTrackingID);
			}
			return S_OK;

			pRequest2->Release();
		}
	}

	CoUninitialize();
	return nRetCode;
}

Creating a CCR through WMI

rslaten — Thu, 15 Jun 2006 00:20:00 GMT


I was recently troubleshooting a problem with the Install Client wizard in the admin console which will be documented in the KB shortly.  To workaround 
the issue I created a script that uses the same WMI methods (CreateCCRs and CreateCCR) that this wizard uses.  This exact script may not be applicable to 
everyone but it does demonstrate how to use the CreateCCR and CreateCCRs methods.  
 
To install the script simply execute the vbs on your SMS Admin console box, then launch the script through the admin console - queries node.

 

'Rslaten 06/01/2006
'VBScript to add a new node to the SMS Admin Console\Queries\ called SMS_Tools\Install Clients
'Once ran from the Admin Console it uses the CreateCCRs WMI method on the SMS_Query instance to create CCRs
'Update:  This VBScript now adds a menu to push a CCR for a single client (result of the query)
'This uses the SMS_Collection::CreateCCR method with the same parameters
'The CCRs created have the following parameters:

'SMS_Query::CreateCCRs method parameters
'PushOnlyAssignedClients = FALSE
'ClientType = 1
'Forced = TRUE
'PushEvenIfDC = FALSE
'InformationOnly = FALSE

'SMS_Collection::CreateCCR method parameters
'ResourceID = 
'PushOnlyAssignedClients = FALSE
'ClientType = 1
'Forced = TRUE
'PushEvenIfDC = FALSE
'InformationOnly = FALSE

Main

Sub Main

	On Error Resume Next
	
	'Check to see if any parameters were passed
	If WScript.Arguments.Count = 0 Then
		'This is being run by a user so create regkeys and copy script to admin console directory
		InstallScript
		WScript.Quit
	Else
		'This is being run from the admin console so continue with CCR creation
		CreateCCRs
	End If

End Sub

'Install routine (only runs if no parameters are passed to script)
Sub InstallScript

	On Error Resume Next
	Dim oShell, sUIPath, oFso, sCurrentDirectory
	Set oShell = CreateObject("WScript.Shell")
	Set oFSO = CreateObject("Scripting.FileSystemObject")
	
	'Get directory of SMS Admin Console
	sUIPath = oShell.RegRead("HKLM\SOFTWARE\Microsoft\SMS\Setup\UI Installation Directory")
	If Err.number <> 0 Then
		WScript.Echo "Failed to get Admin Console Installation Directory from registry"
		WScript.Echo "Error = " & Err.number & " - " & Err.Description
		WScript.Quit
	End If
	
	'Get current directory
	sCurrentDirectory = oShell.CurrentDirectory
	If Err.number <> 0 Then
		WScript.Echo "Failed to get current directory"
		WScript.Echo "Error = " & Err.number & " - " & Err.Description
		WScript.Quit
	End If	
	
	'Create registry key for MMC snapin
	oShell.RegWrite "HKLM\SOFTWARE\Microsoft\MMC\NodeTypes\{58105356-2B9C-11D1-B0D5-00C04FBBD480}" _
	& "\Extensions\SMS_Tools\ForceInstallClient\CommandLine", "wscript.exe " & sUIPath & "\ClientInstall.vbs " _
	& "##SUB:__SERVER## ##SUB:__NAMESPACE## ##SUB:QueryID##"
	If Err.number <> 0 Then
		WScript.Echo "Failed to create MMC snap-in regkey and CommandLine value"
		WScript.Echo "Error = " & Err.number & " - " & Err.Description
		WScript.Quit
	End If
	
	oShell.RegWrite "HKLM\SOFTWARE\Microsoft\MMC\NodeTypes\{58105356-2B9C-11D1-B0D5-00C04FBBD480}" _
	& "\Extensions\SMS_Tools\ForceInstallClient\Description", "Install Client"
	If Err.number <> 0 Then
		WScript.Echo "Failed to create Description regvalue"
		WScript.Echo "Error = " & Err.number & " - " & Err.Description
		WScript.Quit
	End If
	
	oShell.RegWrite "HKLM\SOFTWARE\Microsoft\MMC\NodeTypes\{58105356-2B9C-11D1-B0D5-00C04FBBD480}" _
	& "\Extensions\SMS_Tools\ForceInstallClient\Name", "Install Clients"
	If Err.number <> 0 Then
		WScript.Echo "Failed to create Name regvalue"
		WScript.Echo "Error = " & Err.number & " - " & Err.Description
		WScript.Quit
	End If
	
	oShell.RegWrite "HKLM\SOFTWARE\Microsoft\MMC\NodeTypes\{4D26C0D4-A8A8-11D1-9BD9-00C04FBBD480}" _
	& "\Extensions\SMS_Tools\ForceInstallClient\CommandLine", "wscript.exe " & sUIPath _
	& "\ClientInstall.vbs ##SUB:__SERVER## ##SUB:__NAMESPACE## ##SUB:ResourceID##"
	If Err.number <> 0 Then
		WScript.Echo "Failed to create MMC snap-in regkey and CommandLine value"
		WScript.Echo "Error = " & Err.number & " - " & Err.Description
		WScript.Quit
	End If
	
	oShell.RegWrite "HKLM\SOFTWARE\Microsoft\MMC\NodeTypes\{4D26C0D4-A8A8-11D1-9BD9-00C04FBBD480}" _
	& "\Extensions\SMS_Tools\ForceInstallClient\Description", "Install Client"
	If Err.number <> 0 Then
		WScript.Echo "Failed to create Description regvalue"
		WScript.Echo "Error = " & Err.number & " - " & Err.Description
		WScript.Quit
	End If
	
	oShell.RegWrite "HKLM\SOFTWARE\Microsoft\MMC\NodeTypes\{4D26C0D4-A8A8-11D1-9BD9-00C04FBBD480}" _
	& "\Extensions\SMS_Tools\ForceInstallClient\Name", "Install Client"
	If Err.number <> 0 Then
		WScript.Echo "Failed to create Name regvalue"
		WScript.Echo "Error = " & Err.number & " - " & Err.Description
		WScript.Quit
	End If
	
	'Copy this script to the SMS Admin Console directory
	oFSO.CopyFile WScript.ScriptFullName, sUIPath & "\ClientInstall.vbs"
	If Err.number <> 0 Then
		WScript.Echo "Failed to copy " & sCurrentDirectory & "\ClientInstall.vbs to " & sUIPath & "\"
		WScript.Echo "Error = " & Err.number & " - " & Err.Description
		WScript.Quit
	End If
	
	WScript.Echo "Successfully Installed ClientInstall.vbs onto your SMS Admin Console!"
	
	'Clean up objects
	Set oFSO = Nothing
	Set oShell = Nothing
	
End Sub

'Create CCR routine (only runs if being ran from admin console)
Sub CreateCCRs

	On Error Resume Next
	Dim oWMI, sSMSNamespace, sSMSServer, sQueryID, sResourceID, sTempArg
	
	'Go through parameters passed by script
	Set objArgs = WScript.Arguments
	sTempArg = objArgs(2)

	If IsNumeric(sTempArg) = FALSE Then
		sSMSServer = objArgs(0)
		sSMSNamespace = objArgs(1)
		sQueryID = objArgs(2)
		
		'Connect to WMI
		Set oWMI = GetObject("winMgmts:\\" & sSMSServer & "\" & sSMSNamespace & ":SMS_Query.QueryID='" _
		& sQueryID & "'")
		If Err.number <> 0 Then
			WScript.Echo "Failed to connect to WMI on " & sSMSServer
			WScript.Echo "Error = " & Err.number & " - " & Err.Description
			WScript.Quit
		End If
		
		'Run CreateCCRs Method
		oWMI.CreateCCRs FALSE, 1, TRUE, FALSE, FALSE
		If Err.number <> 0 Then
			WScript.Echo "Failed to run CreateCCRs method on " & sSMSServer
			WScript.Echo "Error = " & Err.number & " - " & Err.Description
			WScript.Quit
		End If
		
		WScript.Echo "Client Install Request(s) Sent Successfully!"
	Else
		sSMSServer = objArgs(0)
		sSMSNamespace = objArgs(1)
		sResourceID = objArgs(2)
		
		'Check to see if we fail to get the 3rd parameter (if so this is an issue with the SMS Admin Console)
		If Err.number <> 0 or sResourceID = "" Then
			sResourceID = InputBox("Please Enter the Resource ID of this Client", "Client Install")
			If sResourceID = "" or IsNumeric(sResourceID) = FALSE Then
				WScript.Echo "Invalid Resource ID!"
				WScript.Quit
			End If
		End If
		
		'Reset Err object
		Err.number = 0
		
		'Connect to WMI
		Set oWMI = GetObject("winMgmts:\\" & sSMSServer & "\" & sSMSNamespace & ":SMS_Collection")
		If Err.number <> 0 Then
			WScript.Echo "Failed to connect to WMI on " & sSMSServer
			WScript.Echo "Error = " & Err.number & " - " & Err.Description
			WScript.Quit
		End If
		
		'Run CreateCCR Method
		oWMI.CreateCCR sResourceID, FALSE, 1, TRUE, FALSE, FALSE
		If Err.number <> 0 Then
			WScript.Echo "Failed to run CreateCCR method on " & sSMSServer
			WScript.Echo "Error = " & Err.number & " - " & Err.Description
			WScript.Quit
		End If
		
		WScript.Echo "Client Install Request Sent Successfully!"
	End If
	
	'Clean up objects
	Set oWMI = Nothing
	
End Sub

Adding a new DP to all existing packages

rslaten — Thu, 08 Jun 2006 19:19:00 GMT

I was recently asked if I had a script to add a new DP to all existing packages in a hierarchy. I wrote something last year that does this. This is a very rough script that was written to actually troubleshoot a specific problem but it might be useful for scenarios like this. It should be noted that this script does need to be cleaned up a bit, error checking added, etc...

The script reads a CSV file that contains a list of primary site servers, child site codes, and package IDs. The script then connects to each primary site server, gets a list of child site codes, gets a list of DPs for the site code listed, and adds every DP at that child site to the package listed.

Here is an example csv file
myCentralSiteServer,CEN,CEN00001
myCentralSiteServer,SEC,CEN00001
myPrimarySiteServer,PRI,CEN00001
myPrimarySiteServer,PRS,PRI00001

So if you ran the script against this CSV file the following would happen:
- Read the CSV file, put this information into an array
- Connect to myCentralSiteServer via WMI
- Get a list of DPs for CEN
- Add all DPs in CEN to CEN00001
- Add all DPs in SEC to CEN00001
- Connect to myPrimarySiteServer via WMI
- Get a list of DPs for PRI
- Add all DPs in PRI to CEN00001
- Add all DPs in PRS to PRI00001

The interesting thing about this script is that it can be used to spread the load of package distribution over your child primary sites instead of distributing all packages from the central site.

Syntax of script: cscript.exe smsdpadd.vbs myCSVfile.csv


 

'Rslaten 04/2005

On Error Resume Next
Dim SMSSites(), ConnTest, SysResList(), AsyncResQuery, AsyncSiteQuery, SiteList(), DPAddArr()
Dim sysrescounter, sitecounter
WScript.Echo "SMS DP Add v1.0"
WScript.Echo ""
GetDPList
StartProcessingLoop

Sub StartProcessingLoop
	On Error Resume Next
	Dim refWMI, SMSNameSpace, refDistPoint
	For i = LBound(SMSSites) to UBound(SMSSites)
		DPInfo = Split(SMSSites(i),",")
		If ConnTest <> DPInfo(0)&",Success" Then
			ConnTestInfo = Split(ConnTest,",")
			If ConnTestInfo(1) <> "Failed" Then
				retval = ConnectToNameSpace(DPInfo(0))
				ConnTest = DPInfo(0)&","&retval
				If ConnTest = DPInfo(0)&",Success" Then
					AsyncResQuery = ""
					AsyncSiteQuery = ""
					GetSysResList(DPInfo(0))
					Do While AsyncResQuery <> "Completed" or AsyncSiteQuery <> "Completed"
						WScript.Sleep 100
					Loop
					CombineArrays
					Set refWMI = GetObject("winMgmts:\\" &DPInfo(0)&"\root\sms")
					Set colNameSpaceQuery = refWMI.ExecQuery("select * from SMS_ProviderLocation")
					For Each refitem in colNameSpaceQuery
						SMSNameSpace = refitem.NamespacePath
					Next
					Set refWMI = Nothing
					Set refWMI = GetObject("winMgmts:" &SMSNameSpace)
					Set refDistPoint = refWMI.Get("SMS_DistributionPoint").SpawnInstance_
				End If
			End If
		End If
		If ConnTest = DPInfo(0)&",Success" Then
			Search = Filter(DPAddArr,"SMS_SITE="&Ucase(DPInfo(1)),TRUE,vbBinaryCompare)
			For y = LBound(Search) to UBound(Search)
				NewVars = Split(Search(y),",")
				refDistPoint.PackageID = DPInfo(2)
				refDistPoint.SiteCode = NewVars(2)
				refDistPoint.ServerNALPath = NewVars(1)
				refDistPoint.SiteName = NewVars(3)
				refDistPoint.Put_()
				WScript.Echo NOW &" - Added DP:" &NewVars(0)& " for Site:" &NewVars(2)&" to Package:"_
				&DPInfo(2)& " at Primary Site:" &DPInfo(0)
			Next
		End If
	Next
End Sub

Sub CombineArrays
	On Error Resume Next
	WScript.Echo "Combining data from arrays"
	ReDim DPAddArr(i)
	For i = 0 to UBound(DPAddArr)
		DPAddArr(i) = ""
	Next
	For i = LBound(SysResList) to UBound(SysResList)
		DP = Split(SysResList(i),",")
		Search = Filter(SiteList,DP(2),TRUE,vbBinaryCompare)
		SiteVars = Split(Search(0),",")
		ReDim Preserve DPAddArr(i)
		DPAddArr(i) = DP(0)&","&DP(1)&","&DP(2)&","&SiteVars(0)
	Next
	WScript.Echo "Done combining data"
End Sub

Sub GetSysResList(server)
	On Error Resume Next
	WScript.Echo "****************************************************"
	WScript.Echo "SMS Primary Site = " &UCase(server)
	WScript.Echo ""
	Dim colSysResQuery, sink, sink2, colSiteQuery, sQuery
	sysrescounter = 0
	sitelistcounter = 0
	Redim SysResList(sysrescounter)
	Redim SiteList(sitelistcounter)
	For i = 0 to UBound(SysResList)
		SysResList(i) = ""
	Next
		For i = 0 to UBound(SiteList)
		SiteList(i) = ""
	Next
	Set refWMI = GetObject("winMgmts:\\" &Server&"\root\sms")
	Set colNameSpaceQuery = refWMI.ExecQuery("select * from SMS_ProviderLocation")
	For Each refitem in colNameSpaceQuery
		SMSNameSpace = refitem.NamespacePath
	Next
	Set refWMI = Nothing
	Set refWMI = GetObject("winMgmts:" &SMSNameSpace)
	WScript.Echo "Querying SMS Database for SysResList data on " &server
	Set sink = wscript.CreateObject("WbemScripting.SWbemSink","SINK_")
	Set sink2 = wscript.CreateObject("WbemScripting.SWbemSink","SINK2_")
	sQuery = "select * from SMS_SystemResourceList WHERE RoleName='SMS Distribution Point'"
	colSysResQuery = refWMI.ExecQueryAsync(sink,sQuery)
	WScript.Echo "Querying SMS Database for Site data on " &server
	colSiteQuery = refWMI.ExecQueryAsync(sink2,"select * from SMS_Site")
End Sub
Sub SINK_OnObjectReady(objObject, objAsyncContext)
	On Error Resume Next
	ReDim Preserve SysResList(sysrescounter)
	SysResList(sysrescounter) = objObject.ServerName& "," &objObject.NALPath& ","_
	&objObject.SiteCode
	sysrescounter = sysrescounter + 1
End Sub
Sub SINK_OnCompleted(iHResult, objErrorObject, objAsyncContext)
	On Error Resume Next
	AsyncResQuery = "Completed"
	WScript.Echo "Done with SysResList data query"
End Sub
Sub SINK2_OnObjectReady(objObject, objAsyncContext)
	On Error Resume Next
	ReDim Preserve SiteList(Sitecounter)
	SiteList(Sitecounter) = objObject.SiteName& "," &objObject.SiteCode
	Sitecounter = Sitecounter + 1
End Sub
Sub SINK2_OnCompleted(iHResult, objErrorObject, objAsyncContext)
	On Error Resume Next
	AsyncSiteQuery = "Completed"
	WScript.Echo "Done with Site data query"
End Sub

Function ConnectToNameSpace(server)
	On Error Resume Next
	Set refWMI = GetObject("winMgmts:\\" & Server & "\root\cimv2")
	If err <> 0 Then
		WScript.Echo "Failed to connect to cimv2 Namespace on " &server
		WScript.Echo "ERROR = " &Err.Description
		ConnectToNameSpace = "Failed"
	Else
		Set refWMI = Nothing
		ConnectToNameSpace = "Success"
	End If
End Function

Sub GetDPList
	On Error Resume Next
	TXTPATH = WScript.Arguments(0)
	WScript.Echo "Getting list of DP's from " &TXTPATH
	Set txtFSO = CreateObject("Scripting.FileSystemObject")
	Set WSHShell = WScript.CreateObject("Wscript.Shell")
	WScript.Echo "****************************************************"
	strdir = WshShell.CurrentDirectory & "\" &TXTPATH
	Set WSHSHell = Nothing
	TXTPATH = strdir
	Set txtInputFile = txtFSO.OpenTextFile(TXTPATH)
	If Err <> 0 Then
		WScript.Echo "Couldn't find " &TXTPATH
		WScript.Echo "Usage: cscript.exe smsdpadd.vbs "
		WScript.Quit
	Else
		While Not txtInputFile.AtEndOfStream
			FullLine = txtInputFile.ReadLine()
			ReDim Preserve SMSSites(SiteCounter)
			SMSSites(SiteCounter) = FullLine
			szSMSSiteQuery = SiteCounter
			SiteCounter = SiteCounter + 1
		Wend
		WScript.Echo "Found " &szSMSSiteQuery + 1 & " sites"
		WScript.Echo "Done building array of Sites"
		WScript.Echo "****************************************************"
		WScript.Echo ""
	End If
End Sub

Introduction to the SMS 2003 Management Point (MP) API

rslaten — Thu, 06 Apr 2006 18:47:00 GMT

The MP API was introduced in the second release of the SMS SDK (we are currently in the fourth release, version 3.1). This API is very powerful and can be used to submit discovery, inventory, status, and metering data from a SMS or non-SMS client. It can also be used to request information from an MP, like policies or the location of a distribution point based on an IP subnet or AD site.

This example shows how to submit a location request to an MP via the MP API. This can be useful for a non-SMS client to be able to find out where to install an SMS package from. A common scenario would be a new install of the OS (maybe right after an image is applied). You could use the MP API to find out where to install the software needed on the image in order to get the machine up to a baseline. I created a win32 console application in Visual Studio and checked the box to add MFC support. For this application to work the smsmsgapi.dll must be registered on the machine (regsvr32 smsmsgapi.dll). Also, make sure smsmsgapi.h and smsmsgapi_i.c are in your project folder. All of these files are included in the SMS SDK.

// LocationRequest.cpp : Defines the entry point for the console application.
// Example of how to submit a location request using the MP API

#include "stdafx.h"
#include "LocationRequest.h"
#include "SmsMsgAPI.h"
#include "SmsMsgAPI_i.c"
#ifdef _DEBUG
#define new DEBUG_NEW
#endif

CWinApp theApp;

using namespace std;

//  Macros to perform error handling and make the code cleaner.
#define _BEGIN \
    HRESULT __hrRetVal = S_OK; \
    { \
 
#define _END \
    } \
    __End: \
 
#define _RETVAL __hrRetVal
 
#define _CHECKHR(expr) if(FAILED(expr)) { __hrRetVal=expr; goto __End; }

//Main
int _tmain(int argc, TCHAR* argv[], TCHAR* envp[])
{
    int nRetCode = 0;

    // initialize MFC and print and error on failure
    if (!AfxWinInit(::GetModuleHandle(NULL), NULL, ::GetCommandLine(), 0))
    {
        _tprintf(_T("Fatal Error: MFC initialization failed\n"));
        nRetCode = 1;
    }
    else
    {
        if(argc < 4)
        {
            printf("Usage:LocationRequest.exe <http://mpname> <CliSubnet> <CliIP> <PkgID> <ADSite>\n");
        }
        else
        {
            CString sMPIP, sClientSubnet, sClientIP, sPackageID, sADSite;
            ISmsMessaging               *pMessaging = NULL;
            ISmsMessage                 *pRequest = NULL;
            ISmsMessage                 *pReply = NULL;
            WCHAR                       *pszRequestMessage = NULL;
            WCHAR                       *pszReplyMessage = NULL;
            CString                        sNewLocationRequest;
            BSTR                        sLocationRequest = NULL;
            BSTR                        sMPIPAddress;

            //Get command line arguments
            sMPIP = argv[1];
            sClientSubnet = argv[2];
            sClientIP = argv[3];
            sPackageID = argv[4];
            sADSite = argv[5];

            //Format XML based Location Request
            sNewLocationRequest = "<ContentLocationRequest SchemaVersion=\"1.0\"> \n \
<Package ID=\"" + sPackageID + "\" Version=\"*\"/> \n \
<AssignedSite SiteCode=\"*\"/> \n \
<ClientLocationInfo> \n \
<ADSite Name=\"" + sADSite + "\"/> \n \
<IPAddresses> \n \
<IPAddress SubnetAddress=\"" + sClientSubnet + "\" Address=\"" + sClientIP + "\"/> \n \
</IPAddresses> \n \
</ClientLocationInfo> \n \
</ContentLocationRequest>";

            printf("\nLocation Request:\n%s",sNewLocationRequest);  //Print request to command line

            sLocationRequest = sNewLocationRequest.AllocSysString();
            sMPIPAddress = sMPIP.AllocSysString();
            CoInitialize(0);

        _BEGIN

            //Create root messaging object
            _CHECKHR( ::CoCreateInstance(
                        CLSID_SmsMessaging,
                        NULL,
                        CLSCTX_INPROC,
                        IID_ISmsMessaging,
                        (LPVOID*)&pMessaging) );

            //Create message object for request
            _CHECKHR( pMessaging->CreateMessage(&pRequest) );

            //Set the target of the message to the Location Manager endpoint
            _CHECKHR( pRequest->SetTargetEndpoint(L"MP_LocationManager") );

            //Set the message body with the request
            _CHECKHR( pRequest->SetBodyFromString(sLocationRequest) );

            // Invoke the targeted endpoint on the local machine with the request,
            // and retrieve the reply.
            _CHECKHR( pMessaging->Invoke(sMPIPAddress, pRequest, &pReply) );

            // Extract body from reply message.
            _CHECKHR( pReply->GetBodyToString(&pszReplyMessage) );

            wprintf(L"\n\nReply from MP:\n%s", (wchar_t *) pszReplyMessage);

        _END

            printf("\n\n%s%X", "Return Code=", __hrRetVal);

            if(pszReplyMessage)
            {
                ::CoTaskMemFree(pszReplyMessage);
            }
            if(pReply)
            {
                pReply->Release();
            }
            if(pszRequestMessage)
            {
                ::CoTaskMemFree(pszRequestMessage);
            }
            if(pRequest)
            {
                pRequest->Release();
            }
            if(pMessaging)
            {
                pMessaging->Release();
            }
        }
    }
    return nRetCode;
}

SMS 2003 Logging

rslaten — Tue, 14 Mar 2006 22:52:00 GMT

SMS 2003 has many different ways to enable additional logging in the product. You should only enable additional logging if troubleshooting a specific issue. Once the issue is resolved disable the logging. Also note, in most cases when logging settings are modified the associated service (smsexec, ccmexec, etc...) needs to be restarted.

Default Logging (KB241001)
Where the SMS Executive service is installed there should be an HKLM\Software\Microsoft\SMS key. Under this key there is a "Tracing" key with different components listed below which contain logging settings. These are enabled by default and the size for each log can be configured here. This can also be configured in the UI by using SMS Service Manager.

Software Metering Processor Logging
Additional logging can be added for the SMS_SOFTWARE_METERING_PROCESSOR component (swmproc.log). You can enable this under HKLM\Software\Microsoft\SMS\Components\SMS_SOFTWARE_METERING_PROCESSOR by setting the "Verbose Logging" value to 1.

Advanced Client/Management Point Logging
The AC/MP logs are very useful but there is additional logging that can be enabled. It is called verbose and debug logging. Go to the section titled "How do I enable DEBUG/VERBOSE logging on the Advanced Client?". This logging simply adds additional entries to the existing AC/MP logs. In addition to this also do the following:
a) Go to the key HKLM\Software\Microsoft\CCM\Logging\DebugLogging
b) Create a new VALUE of type REG_SZ named "Enabled"
c) In the "Enabled" value the data should be "True"

NAL Logging (KB243385)
This logging is only useful on the Legacy client (when communicating with a CAP) or on the site server when communicating with a site system (like a DP). This setting does not create a new log, instead it adds additional entries to the component that is using NAL.

Wuser32 Logging (Legacy Remote Control) (KB195859)
This can be enabled on the client side to assist in troubleshooting remote control issues.

Legacy Client ODP/APM Logging (KB327999)
In SMS 2.0 SP5 some logging was taken out of the Legacy client to make some of the logs easier to read. This change was migrated to the SMS 2003 Legacy client.

Legacy Client Backup Logs
Sometimes when installing the legacy client the install may fail, but not get far enough to create the ms\sms\logs directory structure so you don't have any record of why the install failed. To save these off create a folder called SMSLOGS under %TEMP%. When the install fails again the SMS logs should be in that directory.

SQL Tracing (KB828363)
SQL Tracing is a very useful troubleshooting tool. It adds additional entries to site server components that communicate with the SMS database. The entries it adds are similiar to what you would see if SQL Profiler were running. This option usually adds a lot of data to the logs so it's best to increase the size of your SMS logs (at least for the component you are troubleshooting) so that you can make sure and capture the problem. You might use this logging if inventory wasn't loading into the database properly.

AD Discovery Verbose Logging
You can add additional logging to the following components: Active Directory System Discovery (adsysdis.log), Active Directory System Group Discovery (adsysgrp.log), and Active Directory User Discovery (adusrdis.log). To do this set the "Verbose Logs" value to 1 for one of the following components located under HKLM\Software\Microsoft\SMS\Components:
SMS_AD_SYSTEM_DISCOVERY_AGENT
SMS_AD_SYSTEM_GROUP_DISCOVERY_AGENT
SMS_AD_USER_DISCOVERY_AGENT

SMS Provider Logging (KB295040)
The SMS provider runs under WMI (smsprov.dll) and is responsible for interfacing between the SMS Admin console (SDK) and the SMS SQL database. SQL Cache logging can be enabled for the provider. This is useful when troubleshooting console performance issues.

Verbose WMI Logging (KB317872)
Additional logging can be added for WMI, which is heavily used by the SMS Provider. This is useful when troubleshooting any SMS Admin Console or SDK issue.

Software Inventory Processor Verbose Logging

Thanks to Hans Ravnaas for this information!

More verbose logging can be added to sinvproc.log. This can be configured in the following registry key: HKLM\Software\Microsoft\SMS\Components\SMS_SOFTWARE_INVENTORY_PROCESSOR.
"Verbose Logging"="TRUE"
"ArchiveReports"="TRUE"
"DiskSpaceLimitMB"=dword:00000020
"AgeOutLimitDays"=dword:00000007

The DiskSpaceLimitMB and AgeOutLimitDays values are used to archive inventory reports as they are put into the database. The archive files are stored in SMS\inboxes\sinv.box\Temp. This can be useful when troubleshooting inventory issues at the client. Also note, you can archive the same reports, plus more, on the client.

The following reports will be saved at the client
Hardware Inventory
Software Inventory
Discovery Data
Software Metering usage reports

To configure an SMS 2003 Advanced Client to save off a copy of the report it sends to its MP, create an empty file under the inventory temp directory called archive_reports.sms. The following registry value will point to the inventory temp directory:

HKLM\Software\Microsoft\SMS\Mobile Client\Inventory ----> "Temp Directory".

Examples:

1. To save off inventory reports on a client that is not also an MP, create the
following file:

%systemroot%\system32\ccm\inventory\temp\archive_reports.sms

2. To save off inventory reports on a client that is also an MP, create the
following file:

<x>:\sms_ccm\inventory\temp\archive_reports.sms

The XML file will be saved in the inventory\temp folder.

Note: Delete the archive_reports.sms file when you are done trouble-shooting.

* One additional step is needed to create metering reports. Create a directory under ccm\metering\temp called "archive". The reports will show up there

Getting a list of protected DPs in your hierarchy

rslaten — Mon, 13 Mar 2006 23:34:00 GMT

I was recently asked if there was a way, via the SDK, to list out all your protected DPs and their configured boundaries. I found that this information is available using the SDK but not easily accessible. I have attached a script that is an example of how to do this. It lists out all DPs in your hierarchy, identifies whether they are protected, and then lists any configured boundaries.

-Russ

'Rslaten 03/2006
'Gets protected DPs
'Pass Central site server as first argument
'Needs more error checking added

WScript.Echo ""
WScript.Echo "GetProtectedDPs"
WScript.Echo "Usage: cscript.exe GetProtectedDPs.vbs <CenSiteServerName>"
WScript.Echo "Example: cscript.exe GetProtectedDPs.vbs myCentralSiteServer"
WScript.Echo ""

'Globals
Dim oServices

Main

Sub Main
    On Error Resume Next
    Dim sNameSpace, sSiteServer, sSiteCode, oLocator
    sSiteServer = WScript.Arguments(0)
    sNameSpace = GetSMSNameSpace(sSiteServer)
    sSiteCode = Right(sNameSpace, 3)
    Set oLocator = CreateObject("WbemScripting.SWbemLocator")
    
    'Connect to WMI
    Set oServices = oLocator.ConnectServer(sSiteServer, sNameSpace,,,,,128)
    If Err.number <> 0 Then
        WScript.Echo "Error connecting to " &sNameSpace& " on " &WScript.Arguments(0)& ": " &Err.Number
        Set oLocator = Nothing
        Set oServices = Nothing
        WScript.Quit
    End If    
    
    'Refresh SCF
    RefreshSCF(sSiteCode)
    
    'QueryDPs
    QueryDPs(sSiteCode)
End Sub

'Queries DPs
Sub QueryDPs(sSiteCode)
    Dim collDP, oRes, sStart, aProps, oProp, aPropList, oPropList, oValue
    Set collDP = oServices.ExecQuery("select * from sms_sci_sysresuse where SiteCode = '"&sSiteCode&"'")
    For each oRes in collDP
        If oRes.RoleName = "SMS Distribution Point" Then
            sStart = InStr(oRes.NALPath,"=\\") + 3
            sFinish = InStr(oRes.NALPath,"]MSWNET") - 2
            sDP = mid(oRes.NALPath,sStart,sFinish-sStart)
            WScript.Stdout.Write sDP
            aProps = oRes.Props
            aPropList = oRes.PropLists
            For each oProp in aProps
                If oProp.PropertyName = "IsProtected" Then
                    If oProp.Value = 1 Then
                        WScript.Stdout.Write " (Protected)" & vbCrLf
                    Else
                        WScript.Stdout.Write " (UnProtected)" & vbCrLf
                    End If
                End If
            Next
            For each oPropList in aPropList
                If oPropList.PropertyListName = "Protected Boundary" Then
                    For each oValue in oPropList.Values
                        Select Case oValue
                            Case "IP Subnets"
                                WScript.Stdout.Write vbTab & "Protected Boundary - IP Subnet: "
                            Case "AD Site Name"
                                WScript.Stdout.Write vbTab & "Protected Boundary - AD Site Name: "
                            Case "IP Ranges"
                                WScript.Stdout.Write vbTab & "Protected Boundary - IP Ranges: "
                            Case Else
                                WScript.Stdout.Write oValue & vbCrLf
                        End Select
                    Next            
                End If
            Next
        End If
    Next
    Set collDP = Nothing
End Sub

'Refreshes site control in WMI
Sub RefreshSCF(sSiteCode)
    On Error Resume Next
    Dim sQry, colSysRes
    sQry = "select * from SMS_SiteControlFile where FileType = 1 and SiteCode = '" &sSiteCode& "'"
    Set colSysRes = oServices.ExecQuery(sQry)
    If Err.number <> 0 Then
        WScript.Echo "Unable to query SMS Provider"
        WScript.Echo "Query: " & sQry
        WScript.Echo "Error = " & Err.number & " - " & Err.Description
        WScript.Quit
    End If
    For each SCI in colSysRes
        SCI.Refresh
    Next
    Set colSysRes = Nothing
End Sub

'Gets SMS Namespace
Function GetSMSNameSpace(SiteServer)
    On Error Resume Next
    Dim colNameSpaceQuery, refitem, refWMI
    Set refWMI = GetObject("winMgmts:\\" &SiteServer&"\root\sms")
    If Err.number <> 0 Then
        WScript.Echo "Error connecting to SMS namespace on " &SiteServer
        WScript.Quit
    End If
    Set colNameSpaceQuery = refWMI.ExecQuery("select * from SMS_ProviderLocation")
    For Each refitem in colNameSpaceQuery
        GetSMSNameSpace = refitem.NamespacePath
    Next
    Set colNameSpaceQuery = Nothing
    Set refitem = Nothing
    Set refWMI = Nothing
End Function