Visual Basic Frequently Asked Questions

How can I run another application or batch file from my Visual Basic .NET code?

2004-05-30T08:43:00Z

Posted by: Duncan Mackenzie, MSDN
This post applies to Visual Basic .NET 2002/2003

Suppose you want to run a command line application, open up another Windows program, or even bring up the default web browser or email program... how can you do this from your VB code?

The answer for all of these examples is the same, you can use the classes and methods in System.Diagnostics.Process to accomplish these tasks and more.

Example 1. Running a command line application, without concern for the results:

    Private Sub Button1_Click(ByVal sender As System.Object, _
        ByVal e As System.EventArgs) Handles Button1.Click
        System.Diagnostics.Process.Start("C:\listfiles.bat")
    End Sub

Example 2. Retrieving the results and waiting until the process stops (running the process synchronously):

    Private Sub Button2_Click(ByVal sender As Object, _
        ByVal e As System.EventArgs) Handles Button2.Click
        Dim psi As New _
            System.Diagnostics.ProcessStartInfo("C:\listfiles.bat")
        psi.RedirectStandardOutput = True
        psi.WindowStyle = ProcessWindowStyle.Hidden
        psi.UseShellExecute = False
        Dim listFiles As System.Diagnostics.Process
        listFiles = System.Diagnostics.Process.Start(psi)
        Dim myOutput As System.IO.StreamReader _
            = listFiles.StandardOutput
        listFiles.WaitForExit(2000)
        If listFiles.HasExited Then
            Dim output As String = myOutput.ReadToEnd
            Debug.WriteLine(output)
        End If
    End Sub

Example 3. Displaying a URL using the default browser on the user's machine:

    Private Sub Button3_Click(ByVal sender As System.Object, _
            ByVal e As System.EventArgs) Handles Button3.Click
        Dim myTargetURL As String = "http://www.duncanmackenzie.net"
        System.Diagnostics.Process.Start(myTargetURL)
    End Sub

By the way, you are much better off following the third example for URLs, as opposed to executing IE with the URL as an argument. The code shown here will launch the user's default browser, which may or may not be IE; you are more likely to provide the user with the experience they want and you will be taking advantage of the browser that is most likely to have up-to-date connection information.

How do I determine the difference between two dates?

2004-05-30T08:05:00Z

Posted by: Duncan Mackenzie, MSDN
This post applies to Visual Basic .NET 2002/2003

This common question is often phrased as "How do I find the number of hours between two dates?", substituting minutes, seconds, days, or whatever interval you are looking for in the place of 'hours'. Well, in Visual Basic .NET there are two main ways to achieve this result; the DateDiff function or through the TimeSpan structure.

Both of these methods are equally valid, where they overlap in functionality, but each of them has a couple of unique features. Despite their similar functions, the core difference between the two is that DateDiff is a function, so you need to call it every time you need to retrieve a value, whereas TimeSpan is a structure that is created once and then you just work with its various members as needed.

Using DateDiff, you call it with different date interval parameters to retrieve the appropriate value:

        Dim D1, D2 As Date
        D1 = Date.Now
        D2 = #11/9/2004#
        'DateDiff
        Console.WriteLine("DateDiff")
        Console.WriteLine()
        Console.WriteLine("{0} Days", _
            DateDiff(DateInterval.Day, D1, D2))
        Console.WriteLine("{0} Hours", _
            DateDiff(DateInterval.Hour, D1, D2))
        Console.WriteLine("{0} Minutes", _
            DateDiff(DateInterval.Minute, D1, D2))
        Console.WriteLine("{0} Seconds", _
            DateDiff(DateInterval.Second, D1, D2))
        Console.WriteLine()

Alternatively, a TimeSpan structure can be retrieved as the result of subtracting one date from another, and then querying the various members of that structure.

        'TimeSpan
        Console.WriteLine("TimeSpan")
        Console.WriteLine()
        Dim difference As TimeSpan = D2.Subtract(D1)
        Console.WriteLine("{0} Days", difference.TotalDays)
        Console.WriteLine("{0} Hours", difference.TotalHours)
        Console.WriteLine("{0} Minutes", difference.TotalMinutes)
        Console.WriteLine("{0} Seconds", difference.TotalSeconds)
        Console.WriteLine()

The output of the two different methods is nearly identical, except that the TimeSpan properties are returning Doubles, while DateDiff always returns Longs (Int64).

DateDiff

175 Days
4222 Hours
253345 Minutes
15200730 Seconds

TimeSpan

175.934383644387 Days
4222.42520746528 Hours
253345.512447917 Minutes
15200730.746875 Seconds

The fractional values returned from the TimeSpan properties are more meaningful that they might seem at first glance; each of these properties is returning the complete difference between the two dates, whereas the whole numbers returned from DateDiff only provide a value to within one interval (day, hour, etc…). Using only one of these properties from TimeSpan, it would be possible to figure out any other time interval (with varying degrees of precision, of course), although that calculation would seldom be required in practice.

The TimeSpan structure provides additional members (.Hours, .Days, etc...) that return values closer to what you see from DateDiff, so you can use those if it is more suitable for your situation. While TimeSpan can appear to have more features and to be more efficient, DateDiff has two benefits that may cause you to continue to use it in your Visual Basic .NET applications:

It provides several date intervals that are not covered by TimeSpan, including Weeks and Quarters, and
It is compatible with the VB6 function of the same name, allowing you to more easily reuse existing code.

Read the corresponding documentation for more information, but I hope that this has been helpful...

Multicolumn Combobox?

2004-04-28T07:47:00Z

Posted by: Phil Weber, VB MVP
This post applies to Visual Basic .NET 2002/2003

I see from our referrer logs that many people are coming here seeking information on multicolumn combo boxes (thanks to Ian's question). Here's the scoop...

No, the .NET Framework does not include a multi-column combobox (alternate spelling to help Googlers find us!), but it does provide everything you need to create one. Here are a couple of shared-source implementations:

http://www.vbaccelerator.com/home/NET/Code/Controls/ListBox_and_ComboBox/Icon_ComboBox/article.asp
http://www.codeproject.com/vb/net/multicolumncombo.asp

Can I run Visual Basic 6.0 and Visual Basic .NET on the same machine?

2004-04-26T21:56:00Z

Posted by: Duncan Mackenzie, MSDN
This post applies to Visual Basic .NET 2002/2003 and Visual Basic 6.0

J. Henshaw asks "Is it possible to run both VB6 and VB.Net on the same machine,or do I have to remove VB6 to be able to use VB.NET", and the answer is a definite yes. You can run them both on the same machine.

Many people, including myself, run VB6 on the same machine as their installation of Visual Basic .NET. If you look at this KB article from Microsoft Support, you will even see that it recommended to run VB6 and VB.NET on the same machine when upgrading projects from one to another.

For more information on moving from VB6 to VB.NET, check out this page from the Visual Basic Developer Center.

Does the .NET Framework include an equivalent for [Insert Win32 API function here]?

2004-04-22T13:37:00Z

Posted by: Phil Weber, VB MVP
This post applies to Visual Basic .NET 2002/2003/2005

Judging by the questions I see in online discussion forums, many VB developers are not yet aware of this article, which lists Win32 API functions and their .NET equivalents: http://msdn.microsoft.com/library/en-us/dndotnet/html/win32map.asp

Workaround: Arrays with non-zero lower bounds

2004-04-20T10:59:00Z

Posted by: Phil Weber, VB MVP
This post applies to Visual Basic .NET 2002/2003/2005

OK, now that Paul Vick has explained why VB.NET doesn't support arrays with non-zero lower bounds, let's see how we can do them anyway. ;-)

Say you want to store a collection of annual values in an array of integers. It's reasonable that the array index would correspond to the year in question; that is, TotalSales(1981) would contain the sales total for the year 1981.

In pre-.NET versions of VB, we could simply do this:

    Dim TotalSales(1981 To 2000) As Integer

Problem solved. But as Paul has explained, VB.NET no longer lets us do that. We can, however, do this:

    Dim TotalSales As New VBArray(1981, 2000)
    TotalSales(1981) = 345
    TotalSales(2000) = 995
    Console.WriteLine(TotalSales(1981))
    Console.WriteLine(TotalSales(2000))

I can live with that, how about you?

This class (based on this post by Eric Gunnerson) is what makes it all possible:

Public Class VBArray
     Private _lbound As Integer
     Private _int() As Integer 

     Public Sub New(ByVal LBound As Integer, ByVal UBound As Integer)
         Me.ReDim(LBound, UBound)
     End Sub 

     Public Sub [ReDim](ByVal LBound As Integer, ByVal UBound As Integer)
         _lbound = LBound
         ReDim _int(UBound - LBound + 1)
     End Sub 

     Default Public Property Item(ByVal Index As Integer) As Integer
         Get
             Return _int(Index - _lbound)
         End Get
         Set(ByVal Value As Integer)
             _int(Index - _lbound) = Value
         End Set
     End Property 

     Public Function ToArray() As Integer()
         Return _int
     End Function
 End Class

I've included a ToArray method which returns the underlying array, in case you need to pass it to another method, or manipulate it in other array-type ways.

Note that this class is hard-coded to handle Integers; in VB.NET 2002/2003, you must create a separate class for each array type you wish to simulate. Generics in Visual Basic .NET 2005 will make this sort of thing much cleaner.

Why doesn't VB support non-zero lower bounds for arrays?

2004-04-20T10:01:00Z

Posted by: Duncan Mackenzie, MSDN
This post applies to Visual Basic .NET 2002/2003/2005

Another answer from Paul Vick, Technical Lead on VB.NET, explaining the changes in array bounds from Visual Basic 6.0:

Why doesn't VB support non-zero lower bounds for arrays?
... We allowed programmers to declare arrays that had bounds from 1 to 20, or from 1001 to 2000 or whatever. Even more puzzling, Eric points out that the CLR does support such arrays. So if there's no historical problem and there's no technical problem, why doesn't VB have non-zero lower bound arrays? ...

Why did Visual Basic .NET introduce AndAlso and OrElse?

2004-04-20T07:47:00Z

Posted by: Duncan Mackenzie, MSDN
This post applies to Visual Basic .NET 2002/2003/2005

Paul Vick, Technical Lead on VB.NET, and the author of the Visual Basic .NET Language Specification, discusses the new short-circuiting boolean operators added in Visual Basic .NET 2002.

Why did we introduce AndAlso and OrElse?
... Prior to VB.NET, the VB language only had the And and Or operators. They were essentially bitwise operators, which means that they took their two operands and performed an AND or OR operation on each bit position to produce the resulting bit...

XML Documentation?

2004-04-20T07:23:00Z

Posted by: Phil Weber, VB MVP
This post applies to Visual Basic .NET 2002/2003/2005

Ali Parvaresh asks:

How can I document VB.NET source codes like what you do for C#?

This is another feature scheduled for Visual Basic .NET 2005 (ref http://panopticoncentral.net/archive/2003/11/08/239.aspx). In the meantime, however, there are a number of third-party tools which add this capability to VB.NET 2002/2003. One popular (and free) alternative is the VBCommenter PowerToy.

Operator Overloading?

2004-04-20T06:54:00Z

Posted by: Phil Weber, VB MVP
This post applies to Visual Basic .NET 2005 (“Whidbey”)

Gokhan Altinoren asks:

What was the design decision behind the fact that VB.NET does not support operator overloading? Will this feature be in the VB.NET specification in the future?

Sadly, the VB team failed to consult me while they were designing the language, so I can't comment on why they decided not to support operator overloading in VB.NET (although if I had to guess, I'd wager that it was on the list of “nice-to-have” features that had to be postponed in order to ship VB.NET during the Bush administration).

The good news is that it is slated for the next release of VB (Visual Basic .NET 2005, code-named Whidbey). For more information, see:

http://blogs.gotdotnet.com/cambecc/permalink.aspx/5de5a161-9150-4237-a751-127195cceeab
http://weblogs.asp.net/cfranklin/archive/2003/11/14/37580.aspx

Ask Your VB.NET Questions Here!

2004-04-16T08:01:00Z

Do you have a question about the VB.NET Language, Compiler or IDE?

If so, then you've come to the right place, comment on this post and your question will be added to the list to be answered. Of course, depending on the nature of your comment, and the volume of comments received, we may not get to every question.

Thanks!

Duncan Mackenzie